dev-lang/gnuprologjava/gnuprologjava-0.2.6-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 2016-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="GNU Prolog for Java is an implementation of ISO Prolog as a Java library"
HOMEPAGE="https://www.gnu.org/software/gnuprologjava"
SRC_URI="mirror://gnu/gnuprologjava/${P}-src.zip"

LICENSE="LGPL-3+"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="doc"

BDEPEND="app-arch/unzip"
RDEPEND=">=virtual/jdk-1.6:="
DEPEND="${RDEPEND}
	dev-java/ant-core"

S="${WORKDIR}"

src_prepare() {
	eapply "${FILESDIR}"/${P}-manual.patch
	eapply_user
}

src_compile() {
	eant jar
	if use doc ; then
		eant doc
	fi
	mv build/${P}.jar build/${PN}.jar || die
}

src_install() {
	java-pkg_dojar build/${PN}.jar

	if use doc ; then
		java-pkg_dohtml -r build/api || die
		java-pkg_dohtml -r build/manual || die
	fi

	dodoc NEWS.txt docs/readme.txt
}