dev-java/hamcrest-library/hamcrest-library-1.3-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

JAVA_PKG_IUSE="source"

inherit java-pkg-2 java-pkg-simple

MY_PN=${PN/-library}
MY_P="${MY_PN}-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="Core library of matchers for building test expressions"
HOMEPAGE="https://github.com/hamcrest"
SRC_URI="mirror://gentoo/${MY_P}.tgz"

LICENSE="BSD-2"
SLOT="${PV}"
KEYWORDS="amd64 ~arm ~arm64 ppc64 x86"

DEPEND="dev-java/hamcrest-core:${SLOT}
	>=virtual/jdk-1.8:*
	userland_GNU? ( sys-apps/findutils )"
RDEPEND="dev-java/hamcrest-core:${SLOT}
	>=virtual/jre-1.8:*"
BDEPEND=">=dev-java/hamcrest-generator-${PV}:1.3"

JAVA_SRC_DIR="${PN}/src"
JAVA_GENTOO_CLASSPATH="hamcrest-core-1.3"

DOCS=( {CHANGES,LICENSE,README}.txt )

PATCHES=(
	"${FILESDIR}"/hamcrest-library-1.3-java-11.patch
)

src_prepare() {
	default
	java-pkg_clean
}

src_compile() {
	java-pkg-simple_src_compile

	# Generate "Matchers.java" (java-pkg-simple does not use the "build.xml" file)
	"$(java-config -J)" \
		-cp $(java-config --with-dependencies --classpath hamcrest-core:1.3,hamcrest-generator:1.3):${PN}.jar \
		org.hamcrest.generator.config.XmlConfigurator \
		matchers.xml \
		hamcrest-core/src/main/java,hamcrest-library/src/main/java \
		org.hamcrest.Matchers \
		hamcrest-library/src/main/java

	# Compile again, this time including the freshly generated "Matchers.java"
	java-pkg-simple_src_compile
}

src_install() {
	default
	java-pkg-simple_src_install
}