dev-cpp/nlohmann_json/nlohmann_json-3.7.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit cmake

DESCRIPTION="JSON for Modern C++"
HOMEPAGE="https://github.com/nlohmann/json https://nlohmann.github.io/json/"
SRC_URI="https://github.com/nlohmann/json/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
IUSE="doc test"
RESTRICT="!test? ( test )"

DEPEND="doc? ( app-doc/doxygen )"

DOCS=( ChangeLog.md README.md )

S=${WORKDIR}/json-${PV}

PATCHES=(
	"${FILESDIR}"/${PN}-3.7.3-gcc-10.patch
)

src_configure() {
	local mycmakeargs=(
		-DJSON_BuildTests=$(usex test)
		-DJSON_MultipleHeaders=ON
	)

	cmake_src_configure
}

src_compile() {
	cmake_src_compile
	use doc && emake -C doc
}

src_test() {
	emake check
}

src_install() {
	cmake_src_install
	use doc && dodoc -r doc/html
}