app-vim/vimclojure/vimclojure-2.3.6-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=5

inherit vim-plugin

MY_PN="VimClojure"

DESCRIPTION="vim plugin: Clojure syntax highlighting, filetype and indent settings"
HOMEPAGE="https://github.com/vim-scripts/VimClojure"
SRC_URI="https://github.com/vim-scripts/${MY_PN}/archive/${PV}.zip -> ${P}.zip"
SLOT="0"
LICENSE="BSD"
KEYWORDS="amd64 x86"
IUSE=""

RDEPEND="dev-lang/clojure"

S="${WORKDIR}/${MY_PN}-${PV}"

# Files with similar names are already installed by app-vim/slimv.
DUPLICATE_FILES=(
	indent/clojure.vim
	ftdetect/clojure.vim
)

src_prepare() {
	find . -type f -name \*.bat -exec rm -v {} \; || die

	# Let's simply rename them.
	for file in "${DUPLICATE_FILES[@]}"; do
		[[ -f "${file}" ]] || die "Couldn't find: ${file}"
		bname="${file##*/}"
		path="${file%/*}"
		noext="${bname%%.*}"
		newname="${path}/${PN}_${noext}.vim"
		mv "${file}" "${newname}" || die
	done
}

src_install() {
	local my_license="doc/LICENSE.txt"
	dodoc "${my_license}"
	rm -v "${my_license}" || die
	vim-plugin_src_install
}