blob: fe21830f1857dcb0a03cb2571e5104ed9fbe93d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
PYTHON_COMPAT=( python2_7 )
VALA_USE_DEPEND="vapigen"
inherit autotools bash-completion-r1 gnome2-utils ltprune python-single-r1 vala virtualx
DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
HOMEPAGE="https://github.com/ibus/ibus/wiki"
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="alpha amd64 arm ~arm64 ia64 ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="deprecated gconf gtk +gtk3 +introspection nls +python test vala wayland +X"
RESTRICT="test"
REQUIRED_USE="|| ( gtk gtk3 X )
deprecated? ( python )
vala? ( introspection )
python? (
${PYTHON_REQUIRED_USE}
|| ( deprecated ( gtk3 introspection ) ) )" #342903
CDEPEND="app-text/iso-codes
dev-libs/glib:2
gnome-base/dconf
gnome-base/librsvg:2
sys-apps/dbus[X?]
x11-libs/libnotify
gconf? ( gnome-base/gconf:2 )
gtk? ( x11-libs/gtk+:2 )
gtk3? ( x11-libs/gtk+:3 )
introspection? ( dev-libs/gobject-introspection )
nls? ( virtual/libintl )
python? (
${PYTHON_DEPS}
dev-python/pygobject:3[${PYTHON_USEDEP}]
)
wayland? (
dev-libs/wayland
x11-libs/libxkbcommon
)
X? (
|| (
x11-libs/gtk+:3
x11-libs/gtk+:2
)
x11-libs/libX11
)"
RDEPEND="${CDEPEND}
python? (
deprecated? (
dev-python/dbus-python[${PYTHON_USEDEP}]
dev-python/pygtk:2[${PYTHON_USEDEP}]
)
gtk3? (
x11-libs/gtk+:3[introspection]
)
)"
DEPEND="${CDEPEND}
dev-util/intltool
virtual/pkgconfig
nls? ( sys-devel/gettext )
vala? ( $(vala_depend) )"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
use vala && vala_src_prepare
# fix for parallel install
sed -i \
-e "/^py2_compile/,/^$/d" \
-e "/^install-data-hook/,/^$/d" \
bindings/pygobject/Makefile.am
sed -i "/^bash_completion/d" tools/Makefile.am
default
eautoreconf
}
src_configure() {
local python_conf=()
if use python; then
python_conf+=(
$(use_enable deprecated python-library)
$(use_enable gtk3 setup)
--with-python=${EPYTHON}
)
else
python_conf+=( --disable-setup )
fi
econf \
$(use_enable gconf) \
$(use_enable gtk gtk2) \
$(use_enable gtk3 ui) \
$(use_enable gtk3) \
$(use_enable introspection) \
$(use_enable nls) \
$(use_enable test tests) \
$(use_enable vala) \
$(use_enable wayland) \
$(use_enable X xim) \
"${python_conf[@]}"
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
virtx emake -j1 check
}
src_install() {
default
prune_libtool_files --modules
keepdir /usr/share/ibus/engine
newbashcomp tools/${PN}.bash ${PN}
insinto /etc/X11/xinit/xinput.d
newins xinput-${PN} ${PN}.conf
}
pkg_preinst() {
use gconf && gnome2_gconf_savelist
gnome2_icon_savelist
gnome2_schemas_savelist
}
pkg_postinst() {
use gconf && gnome2_gconf_install
use gtk && gnome2_query_immodules_gtk2
use gtk3 && gnome2_query_immodules_gtk3
gnome2_icon_cache_update
gnome2_schemas_update
}
pkg_postrm() {
use gtk && gnome2_query_immodules_gtk2
use gtk3 && gnome2_query_immodules_gtk3
gnome2_icon_cache_update
gnome2_schemas_update
}
|
GitWeb