app-emacs/auto-complete/auto-complete-1.5.1-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit elisp

DESCRIPTION="Auto-complete package"
HOMEPAGE="https://github.com/auto-complete/auto-complete/"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3+ FDL-1.1+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"
RESTRICT="test"

RDEPEND="app-emacs/popup"
BDEPEND="${RDEPEND}
	doc? ( virtual/pandoc )"

ELISP_REMOVE="${PN}-pkg.el"
SITEFILE="50${PN}-gentoo.el"

src_compile() {
	elisp_src_compile
	use doc && emake -C doc
}

src_install() {
	elisp_src_install

	# install dictionaries
	insinto "${SITEETC}/${PN}"
	doins -r dict

	dodoc README.md TODO.md etc/test.txt
	if use doc; then
		docinto html
		dodoc doc/manual.html doc/changes.html doc/style.css doc/*.png
	fi
}