app-crypt/acme-sh/acme-sh-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit git-r3 optfeature

DESCRIPTION="A pure Unix shell script implementing ACME client protocol"
HOMEPAGE="https://github.com/acmesh-official/acme.sh"
EGIT_REPO_URI="https://github.com/acmesh-official/${PN/-/.}.git"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""

RDEPEND="
	dev-libs/openssl:0
	net-misc/curl
	net-misc/socat
"

src_install() {
	newdoc deploy/README.md README-deploy.md
	newdoc dnsapi/README.md README-dnsapi.md
	rm {deploy,dnsapi}/README.md || die
	einstalldocs

	exeinto /usr/share/acme.sh
	doexe acme.sh

	insinto /usr/share/acme.sh
	doins -r deploy dnsapi notify

	keepdir /etc/acme-sh
	doenvd "${FILESDIR}"/99acme-sh

	insinto /etc/bash/bashrc.d
	doins "${FILESDIR}"/acme.sh

	dosym ../share/acme.sh/acme.sh usr/bin/acme.sh
}

pkg_postinst() {
	einfo "If you wish to use the webserver mode,"
	einfo "you need to install a supported web server."
	optfeature "using apache2 webserver mode." www-servers/apache
	optfeature "using nginx webserver mode." www-servers/nginx
}