1 files changed, 63 insertions, 0 deletions
diff --git a/x11-proto/xcb-proto/xcb-proto-1.9-r1.ebuild b/x11-proto/xcb-proto/xcb-proto-1.9-r1.ebuild
new file mode 100644
index 000000000000..627c706b4d7c
--- /dev/null
+++ b/x11-proto/xcb-proto/xcb-proto-1.9-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3} )
+XORG_MULTILIB=yes
+
+inherit python-r1 xorg-2
+
+DESCRIPTION="X C-language Bindings protocol headers"
+HOMEPAGE="http://xcb.freedesktop.org/"
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/xcb/proto"
+[[ ${PV} != 9999* ]] && \
+	SRC_URI="http://xcb.freedesktop.org/dist/${P}.tar.bz2"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	dev-libs/libxml2"
+
+# Work around py-compile being generated by some ancient version.
+src_prepare() {
+	rm -f py-compile
+	eautoreconf
+
+	# Remove tabs, bug 490928.
+	sed -i -e 's/	/    /' xcbgen/xtypes.py || die
+}
+
+src_configure() {
+	python_export_best
+	xorg-2_src_configure
+}
+
+multilib_src_configure() {
+	autotools-utils_src_configure
+
+	if multilib_is_native_abi; then
+		python_parallel_foreach_impl autotools-utils_src_configure
+	fi
+}
+
+multilib_src_compile() {
+	default
+
+	if multilib_is_native_abi; then
+		python_foreach_impl autotools-utils_src_compile -C xcbgen \
+			top_builddir="${BUILD_DIR}"
+	fi
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi; then
+		python_foreach_impl autotools-utils_src_install -C xcbgen \
+			top_builddir="${BUILD_DIR}"
+	fi
+}