1 files changed, 57 insertions, 0 deletions
diff --git a/sys-devel/autoconf/autoconf-2.69-r5.ebuild b/sys-devel/autoconf/autoconf-2.69-r5.ebuild
new file mode 100644
index 000000000000..a51dccb3f741
--- /dev/null
+++ b/sys-devel/autoconf/autoconf-2.69-r5.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/autoconf.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
+		ftp://alpha.gnu.org/pub/gnu/${PN}/${P}.tar.xz
+		https://dev.gentoo.org/~polynomial-c/dist/${P}-runstatedir_patches.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+inherit toolchain-autoconf
+
+DESCRIPTION="Used to create autoconfiguration files"
+HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
+
+LICENSE="GPL-3"
+SLOT="${PV}"
+IUSE="emacs"
+
+BDEPEND=">=sys-devel/m4-1.4.16
+	>=dev-lang/perl-5.6"
+RDEPEND="${BDEPEND}
+	!~sys-devel/${P}:2.5
+	>=sys-devel/autoconf-wrapper-13"
+[[ ${PV} == "9999" ]] && BDEPEND+=" >=sys-apps/texinfo-4.3"
+PDEPEND="emacs? ( app-emacs/autoconf-mode )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.69-perl-5.26.patch
+	"${FILESDIR}"/${P}-fix-libtool-test.patch
+	"${FILESDIR}"/${PN}-2.69-perl-5.26-2.patch
+
+	"${WORKDIR}"/patches/${P}-runstatedir.patch
+	"${WORKDIR}"/patches/${P}-texinfo.patch
+	"${WORKDIR}"/patches/${P}-runstatedir_info.patch
+)
+
+src_prepare()   {
+	# usr/bin/libtool is provided by binutils-apple, need gnu libtool
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		PATCHES+=( "${FILESDIR}"/${PN}-2.61-darwin.patch )
+	fi
+
+	# Save timestamp to avoid later makeinfo call
+	touch -r doc/{,old_}autoconf.texi || die
+
+	toolchain-autoconf_src_prepare
+
+	# Restore timestamp to avoid makeinfo call
+	# We already have an up to date autoconf.info page at this point.
+	touch -r doc/{old_,}autoconf.texi || die
+}