1 files changed, 35 insertions, 0 deletions
diff --git a/sys-cluster/kube-proxy/kube-proxy-1.29.3.ebuild b/sys-cluster/kube-proxy/kube-proxy-1.29.3.ebuild
new file mode 100644
index 000000000000..a88d05e60e65
--- /dev/null
+++ b/sys-cluster/kube-proxy/kube-proxy-1.29.3.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit go-module
+
+DESCRIPTION="Kubernetes Proxy service"
+HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
+SRC_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="hardened"
+
+RDEPEND="net-firewall/conntrack-tools"
+BDEPEND=">=dev-lang/go-1.20"
+
+RESTRICT+=" test"
+S="${WORKDIR}/kubernetes-${PV}"
+
+src_compile() {
+	CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')" \
+		emake -j1 GOFLAGS="" GOLDFLAGS="" LDFLAGS="" FORCE_HOST_GO=yes \
+		WHAT=cmd/${PN}
+}
+
+src_install() {
+	dobin _output/bin/${PN}
+	keepdir /var/log/${PN} /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotated ${PN}
+}