1 files changed, 39 insertions, 0 deletions
diff --git a/net-p2p/tremc/tremc-0.9.2.ebuild b/net-p2p/tremc/tremc-0.9.2.ebuild
new file mode 100644
index 000000000000..2c02ce97e8da
--- /dev/null
+++ b/net-p2p/tremc/tremc-0.9.2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+PYTHON_REQ_USE="ncurses"
+inherit bash-completion-r1 eutils python-single-r1
+
+DESCRIPTION="Ncurses interface for the Transmission BitTorrent client"
+HOMEPAGE="https://github.com/tremc/tremc"
+SRC_URI="https://github.com/tremc/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+
+# Specify a no-op src_compile so upstream's broken Makefile doesn't get used
+src_compile() {
+	:
+}
+
+src_install() {
+	python_doscript tremc
+	newbashcomp completion/bash/tremc.sh tremc
+	insinto /usr/share/zsh/site-functions
+	doins completion/zsh/_tremc
+	doman tremc.1
+	dodoc NEWS README.md
+}
+
+pkg_postinst() {
+	optfeature "GeoIP support" dev-python/geoip-python
+	optfeature "Extract ipv4 from ipv6 addresses" dev-python/ipy
+	optfeature "Clipboard support" dev-python/pyperclip
+}