2 files changed, 68 insertions, 0 deletions
diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index d3d502622068..719551d3da8f 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1 +1,2 @@
 DIST ownCloud-2.11.1.8946.tar.xz 5654496 BLAKE2B 6b5b82730460071ae590b35d653824f4e56d506d87929c5d4ebb31eef921d0cb0141a44d7f0c996b8d1afffa5874d3e4dda75feaba740e652df2939633475fcd SHA512 b44f72e22c539a731901d9c146f00edbf0a4dabb992d6cde06be1b50506d5bc4a8aa861c6ea0207eed72aaea8c8af8651ce07f9e9154e6e44ccdecdd27e35b75
+DIST ownCloud-3.1.0.9872.tar.xz 5682584 BLAKE2B 174ffd7d441883f61817a6ab63decdd0238b9eb05d4e9cf0d5d18e69e6d2b08ad7836f7396383888f6f7d2f0d1be740c58413cd876780dba12446c6918921a47 SHA512 ca64af7c6ece1f26778a58088fcceaa68cddf1856ad7f1f5f24ee85691c813aed58339690ded1d0c535c131b2cf0343a03fe53289914bf36fa5ad4034f223b3e
diff --git a/net-misc/owncloud-client/owncloud-client-3.1.0.9872.ebuild b/net-misc/owncloud-client/owncloud-client-3.1.0.9872.ebuild
new file mode 100644
index 000000000000..1eed40954de2
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-3.1.0.9872.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+MY_PN="ownCloud"
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/${MY_PN}/stable/${PV}/source/${MY_PN}-${PV}.tar.xz"
+S=${WORKDIR}/${MY_PN}-${PV}
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dolphin gnome-keyring nautilus test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring?,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+DEPEND="${RDEPEND}
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules"
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}