3 files changed, 77 insertions, 2 deletions
diff --git a/net-libs/libtrace/Manifest b/net-libs/libtrace/Manifest
index f3c34fedffa8..53a961ba3b97 100644
--- a/net-libs/libtrace/Manifest
+++ b/net-libs/libtrace/Manifest
@@ -1 +1,2 @@
 DIST libtrace-4.0.15_p1.tar.gz 1891845 BLAKE2B 08faf395f5fdda21829b89a9276649b297d2266ef10d2162b588b39d4d8d2da1306c74bb180d63b92f4422bb157fb451d34cd8167f0bff42322776e3b1ee0e7c SHA512 82f18b03e824f3ac89330854c3659244106ab5323f5e7a43ec7d2280f6ad3d427a906708688469b3f5aa479d11fef99a4bbecea585b81c916029132375582a4e
+DIST libtrace-4.0.17_p1.tar.gz 1961123 BLAKE2B be961bc58496414415b9affb0a6b77e5f234b92196fb719f3a2e8058ae80ade90977c44d57c75d37cbf26ff2e0c8816a4b376b77b6e44d13833960c6095b7e2c SHA512 85280edd515acf52361c34ebe5324fd95f4fafc72aa22c2c8bd43a6bca9a6b5fc9a046480fc760bb39d8b577532ed416caf10a630cea9465d305f2ed4dcb318e
diff --git a/net-libs/libtrace/libtrace-4.0.17_p1.ebuild b/net-libs/libtrace/libtrace-4.0.17_p1.ebuild
new file mode 100644
index 000000000000..fedc23bfe00e
--- /dev/null
+++ b/net-libs/libtrace/libtrace-4.0.17_p1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A library and tools for trace processing"
+HOMEPAGE="https://research.wand.net.nz/software/libtrace.php"
+SRC_URI="https://github.com/${PN^}Team/${PN}/archive//${PV/_p/-}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/_p/-}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ncurses numa"
+
+BDEPEND="
+	app-doc/doxygen[dot]
+	sys-devel/flex
+	virtual/os-headers
+	virtual/pkgconfig
+	virtual/yacc
+"
+RDEPEND="
+	>=net-libs/libpcap-0.8
+	dev-libs/libyaml
+	dev-libs/openssl:0=
+	net-libs/wandio
+	ncurses? ( sys-libs/ncurses:0= )
+	numa? ( sys-process/numactl )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.20-autoconf-1.13.patch
+	"${FILESDIR}"/${PN}-4.0.0-no-examples.patch
+	"${FILESDIR}"/${PN}-4.0.0-with-numa.patch
+	"${FILESDIR}"/${PN}-4.0.9_p1-tinfo.patch
+)
+
+src_prepare() {
+	default
+
+	mv configure.{in,ac} || die
+
+	eautoreconf
+
+	# Comment out FILE_PATTERNS definition (bug #706230)
+	if has_version ~app-doc/doxygen-1.8.16; then
+		sed -i -e '/^FILE_PATTERNS/s|^|#|g' docs/${PN}.doxygen.in || die
+	fi
+
+	# Update doxygen configuration
+	doxygen -u docs/libtrace.doxygen.in || die
+}
+
+src_configure() {
+	econf \
+		$(use_with ncurses) \
+		$(use_with numa) \
+		--with-man \
+		--without-dpdk
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		docinto html
+		dodoc -r docs/doxygen/html
+	fi
+
+	find "${ED}" -name "*.la" -delete || die
+}
diff --git a/net-libs/libtrace/libtrace-9999.ebuild b/net-libs/libtrace/libtrace-9999.ebuild
index 08a6c74711ba..f8ed9c02d13b 100644
--- a/net-libs/libtrace/libtrace-9999.ebuild
+++ b/net-libs/libtrace/libtrace-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit autotools git-r3
 
@@ -57,7 +57,6 @@ src_configure() {
 	econf \
 		$(use_with ncurses) \
 		$(use_with numa) \
-		--disable-static \
 		--with-man
 }