1 files changed, 54 insertions, 0 deletions
diff --git a/media-libs/libtgvoip/libtgvoip-2.4.4_p20200123.ebuild b/media-libs/libtgvoip/libtgvoip-2.4.4_p20200123.ebuild
new file mode 100644
index 000000000000..06ad597854cc
--- /dev/null
+++ b/media-libs/libtgvoip/libtgvoip-2.4.4_p20200123.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+EGIT_COMMIT="c5651ffc728336e56d8567f5c6c179e8a5d4fe55"
+
+DESCRIPTION="VoIP library for Telegram clients"
+HOMEPAGE="https://github.com/telegramdesktop/libtgvoip"
+SRC_URI="https://github.com/telegramdesktop/libtgvoip/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE="alsa +dsp libressl pulseaudio"
+
+DEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	media-libs/opus
+	alsa? ( media-libs/alsa-lib )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+REQUIRED_USE="|| ( alsa pulseaudio )"
+
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+PATCHES=( "${FILESDIR}/2.4.4-pulseaudio.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--disable-static
+		$(use_enable dsp)
+		$(use_with alsa)
+		$(use_with pulseaudio pulse)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}