3 files changed, 84 insertions, 0 deletions
diff --git a/games-board/ace/ace-1.4-r2.ebuild b/games-board/ace/ace-1.4-r2.ebuild
new file mode 100644
index 000000000000..e2c67ef401e5
--- /dev/null
+++ b/games-board/ace/ace-1.4-r2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop
+
+DESCRIPTION="DJ Delorie's Ace of Penguins solitaire games"
+HOMEPAGE="http://www.delorie.com/store/ace/"
+SRC_URI="http://www.delorie.com/store/ace/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	media-libs/libpng:0=
+	x11-libs/libX11"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-no-xpm.patch
+	"${FILESDIR}"/${P}-libpng15.patch
+	"${FILESDIR}"/${P}-gold.patch
+	"${FILESDIR}"/${P}-CC.patch
+	"${FILESDIR}"/${P}-clang.patch
+	"${FILESDIR}/${P}-gcc10.patch"
+	"${FILESDIR}/${P}-malloc.patch"
+)
+
+src_prepare() {
+	default
+
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--program-prefix=ace-
+}
+
+src_install() {
+	default
+
+	rm "${ED}/usr/$(get_libdir)/libcards.la" || die
+	dodoc docs/*
+	newicon docs/as.gif ${PN}.gif
+	cd "${ED}/usr/bin" || die
+	local p
+	for p in *
+	do
+		make_desktop_entry $p "Ace ${p/ace-/}" /usr/share/pixmaps/${PN}.gif
+	done
+}
diff --git a/games-board/ace/files/ace-1.4-gcc10.patch b/games-board/ace/files/ace-1.4-gcc10.patch
new file mode 100644
index 000000000000..23324d585a04
--- /dev/null
+++ b/games-board/ace/files/ace-1.4-gcc10.patch
@@ -0,0 +1,16 @@
+Author: Reiner Herrmann <reiner@reiner-h.de>
+Description: Fix FTBFS with GCC 10
+ Use extern keyword, as linker otherwise sees multiple definitions.
+Bug-Debian: https://bugs.debian.org/956976
+
+--- a/lib/table.c
++++ b/lib/table.c
+@@ -53,7 +53,7 @@
+ static int graphics_disabled = 1;
+ 
+ OptionDesc *app_options;
+-OptionDesc *xwin_options;
++extern OptionDesc *xwin_options;
+ static OptionDesc *options[5];
+ 
+ static OptionDesc ace_options[] = {
diff --git a/games-board/ace/files/ace-1.4-malloc.patch b/games-board/ace/files/ace-1.4-malloc.patch
new file mode 100644
index 000000000000..da9b3b24f82c
--- /dev/null
+++ b/games-board/ace/files/ace-1.4-malloc.patch
@@ -0,0 +1,10 @@
+Avoid warning about implicit malloc()
+
+diff -r 587fa6195b61 lib/imagelib.c
+--- a/lib/imagelib.c	Mon Oct 05 22:08:52 2020 +0000
++++ b/lib/imagelib.c	Mon Oct 05 22:09:12 2020 +0000
+@@ -1,3 +1,4 @@
++#include <stdlib.h>
+ #include <stdio.h>
+ #include <string.h>
+ #include "imagelib.h"