3 files changed, 85 insertions, 2 deletions
diff --git a/dev-vcs/tortoisehg/Manifest b/dev-vcs/tortoisehg/Manifest
index 781ac03dd608..bb5d8b056c04 100644
--- a/dev-vcs/tortoisehg/Manifest
+++ b/dev-vcs/tortoisehg/Manifest
@@ -1,3 +1,4 @@
 DIST tortoisehg-5.9.3.tar.gz 8637453 BLAKE2B 9fa90c108f32b1e15c233e7ccbadbda08e434f23aa5c5fe7c235c743c98f54f4222a1804c06b0ca300cc3d0b049c117007a53452ff20ae4411bca30d8ed9013b SHA512 870b3b717962b8450d07fca5300f971d187236edce5a9d2926144b832c0771b8f5a324bdfd05a1fed3d2b4de4bad913c0c8f4435908e602e268c561ed64abbb2
 DIST tortoisehg-6.2.1.tar.gz 8877912 BLAKE2B c3741c89656e339c37238208c639717e95a8de40ab84e3dbcf151e97e9a51674ca481f7bacbe2cdf90a8b80e15f2cd10a13317b0da691ebb3103f1a460bbdb03 SHA512 282dfc765a57d8d47c81f68e72b22ac56e6d67b7eb2a76cb999880ed225067c590507af95629c621b129bdb6212450cf666aa72da7907584373f3a56fbfd6bcc
 DIST tortoisehg-6.2.3.tar.gz 8878641 BLAKE2B ede267f48c7b58db1fcdf16a11fb343e4fcf21193a43f6d6114ef6f930946beea458acc52780deaa889d429989c7b8b25045a9ed340297c0d1ee7e5e5e998d2a SHA512 8c7e62822bdbdcae7a371b910e3e549864019b3a74a090e59d0f26291525ebda078de3f41d8442b457e14727ec94143290d0f3fac9f49cbe842d1de298ae2edd
+DIST tortoisehg-6.3.2.tar.gz 8885325 BLAKE2B bb9a7043f7d2e44b32e20b6dd88372927977a6fd94b662a8a56d26776c72268e0953de3edc93b2f7b9efc580286632f500f5181a5ef7bf3edd3fb5ba5ec64761 SHA512 b711f9d347b2f00978b42b258713d365188c4de100668a09fea4b6f80bb8083a7980a462b8fb4705d31f9da310dbdeb2d9891e93f6e3f6f2833e4c7ccfa4d800
diff --git a/dev-vcs/tortoisehg/tortoisehg-6.3.2.ebuild b/dev-vcs/tortoisehg/tortoisehg-6.3.2.ebuild
new file mode 100644
index 000000000000..b14e5b79045a
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-6.3.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature xdg-utils
+
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~arm64 ~x86"
+	SRC_URI="https://foss.heptapod.net/mercurial/${PN}/thg/-/archive/${PV}/thg-${PV}.tar.gz -> ${P}.tar.gz"
+	HG_DEPEND=">=dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '>=dev-vcs/mercurial-6.3.2[${PYTHON_USEDEP}]' python3_11 )
+		<dev-vcs/mercurial-6.4[${PYTHON_USEDEP}]"
+	S="${WORKDIR}/thg-${PV}"
+else
+	inherit mercurial
+	EHG_REPO_URI="https://foss.heptapod.net/mercurial/${PN}/thg"
+	EHG_REVISION="stable"
+	HG_DEPEND=">=dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${HG_DEPEND}
+	dev-python/iniparse[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
+	>=dev-python/qscintilla-python-2.11.6[qt5(+),${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc/source
+
+python_prepare_all() {
+	# Remove file that collides with >=mercurial-4.0 (bug #599266).
+	rm "${S}"/hgext3rd/__init__.py || die "can't remove /hgext3rd/__init__.py"
+
+	sed -i -e 's:share/doc/tortoisehg:share/doc/'"${PF}"':' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	${EPYTHON} tests/run-tests.py -m 'not largefiles' --disable-pytest-warnings --doctest-modules tests || die "Tests failed with ${EPYTHON}"
+	${EPYTHON} tests/run-tests.py -m largefiles --disable-pytest-warnings tests || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+	newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+	domenu contrib/thg.desktop
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	elog "When startup of ${PN} fails with an API version mismatch error"
+	elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
+	elog "dev-python/qscintilla-python."
+
+	optfeature "the core git extension support" dev-python/pygit2
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/dev-vcs/tortoisehg/tortoisehg-9999.ebuild b/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
index c4e1efd98699..b14e5b79045a 100644
--- a/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
+++ b/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..10} )
+PYTHON_COMPAT=( python3_{9..11} )
 DISTUTILS_USE_PEP517=setuptools
 
 inherit desktop distutils-r1 optfeature xdg-utils
@@ -12,7 +12,8 @@ if [[ ${PV} != *9999* ]]; then
 	KEYWORDS="~amd64 ~arm64 ~x86"
 	SRC_URI="https://foss.heptapod.net/mercurial/${PN}/thg/-/archive/${PV}/thg-${PV}.tar.gz -> ${P}.tar.gz"
 	HG_DEPEND=">=dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]
-		<dev-vcs/mercurial-6.3[${PYTHON_USEDEP}]"
+		$(python_gen_cond_dep '>=dev-vcs/mercurial-6.3.2[${PYTHON_USEDEP}]' python3_11 )
+		<dev-vcs/mercurial-6.4[${PYTHON_USEDEP}]"
 	S="${WORKDIR}/thg-${PV}"
 else
 	inherit mercurial