1 files changed, 61 insertions, 0 deletions
diff --git a/dev-scheme/gauche/gauche-0.9.9-r1.ebuild b/dev-scheme/gauche/gauche-0.9.9-r1.ebuild
new file mode 100644
index 000000000000..f352c5b1acad
--- /dev/null
+++ b/dev-scheme/gauche/gauche-0.9.9-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit autotools
+
+MY_P="${P^g}"
+
+DESCRIPTION="A Unix system friendly Scheme Interpreter"
+HOMEPAGE="http://practical-scheme.net/gauche/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tgz"
+
+LICENSE="BSD"
+SLOT="0/$(ver_cut 1-2)7"
+KEYWORDS="~alpha amd64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
+IUSE="ipv6 mbedtls test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/gdbm
+	virtual/libcrypt:=
+	mbedtls? ( net-libs/mbedtls:= )"
+DEPEND="${RDEPEND}
+	test? (
+		dev-libs/openssl:0
+	)"
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-ext-ldflags.patch
+	"${FILESDIR}"/${PN}-gauche.m4.patch
+	"${FILESDIR}"/${PN}-info.patch
+	"${FILESDIR}"/${PN}-rfc.tls.patch
+	"${FILESDIR}"/${P}-xz-info.patch
+)
+DOCS=( AUTHORS ChangeLog HACKING.adoc README.adoc )
+
+src_prepare() {
+	default
+	use ipv6 && sed -i "s/ -4//" ext/tls/ssltest-mod.scm
+
+	eautoconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable ipv6) \
+		--with-ca-bundle="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
+		--with-libatomic-ops=no \
+		--with-slib="${EPREFIX}"/usr/share/slib \
+		--with-tls=axtls$(usex mbedtls ',mbedtls' '')
+}
+
+src_test() {
+	emake -j1 -s check
+}
+
+src_install() {
+	emake DESTDIR="${D}" install-pkg install-doc
+	einstalldocs
+}