1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/pythong/pythong-2.1.5-r2.ebuild b/dev-python/pythong/pythong-2.1.5-r2.ebuild
new file mode 100644
index 000000000000..989a5417abaa
--- /dev/null
+++ b/dev-python/pythong/pythong-2.1.5-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+PYTHON_REQ_USE="tk"
+
+inherit python-single-r1
+
+MY_PN="pythonG"
+MY_PV=${PV/_/-}
+MY_PV=${MY_PV//\./_}
+
+DESCRIPTION="Nice and powerful spanish development environment for Python"
+HOMEPAGE="http://www3.uji.es/~dllorens/PythonG/principal.html"
+SRC_URI="
+	http://www3.uji.es/~dllorens/downloads/pythong/linux/${MY_PN}-${MY_PV}.tgz
+	doc? ( http://marmota.act.uji.es/MTP/pdf/python.pdf )"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ia64 x86"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="
+	>=dev-lang/tk-8.3.4:0=
+	virtual/pmw[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+src_prepare() {
+	sed \
+		-e "s:^\(fullpath = \).*:\1'$(python_get_sitedir)':" \
+		-e "/^url_docFuncPG/s:'+fullpath+':/usr/share/doc/${PF}:" \
+		-i pythong.py || die "sed in pythong.py failed"
+}
+
+src_install() {
+	python_domodule modulepythong.py libpythong
+	python_doscript pythong.py
+
+	dodoc leeme.txt
+	insinto /usr/share/doc/${PF}
+	doins -r {LICENCIA,MANUAL,demos}
+	rm -fr "${ED}/usr/share/doc/${PF}/demos/modulepythong.py" || die
+
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins "${DISTDIR}"/python.pdf
+	fi
+	python_optimize
+}