1 files changed, 54 insertions, 0 deletions
diff --git a/dev-python/pydl/pydl-0.5.3.ebuild b/dev-python/pydl/pydl-0.5.3.ebuild
new file mode 100644
index 000000000000..10d305a3fcbc
--- /dev/null
+++ b/dev-python/pydl/pydl-0.5.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Library of IDL astronomy routines converted to Python"
+HOMEPAGE="https://pypi.python.org/pypi/pydl/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+PATCHES=( ${FILESDIR}/${PN}-ignore_entry_points.patch )
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}