1 files changed, 50 insertions, 0 deletions
diff --git a/dev-libs/libuv/libuv-1.21.0-r1.ebuild b/dev-libs/libuv/libuv-1.21.0-r1.ebuild
new file mode 100644
index 000000000000..5a5b2d1a24a9
--- /dev/null
+++ b/dev-libs/libuv/libuv-1.21.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools ltprune multilib-minimal
+
+DESCRIPTION="Cross-platform asychronous I/O"
+HOMEPAGE="https://github.com/libuv/libuv"
+SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD BSD-2 ISC MIT"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+RESTRICT="test"
+
+DEPEND="sys-devel/libtool
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+PATCHES=(
+	"${FILESDIR}"/${P}-UV_FS_LCHOWN.patch
+)
+
+src_prepare() {
+	default
+
+	echo "m4_define([UV_EXTRA_AUTOMAKE_FLAGS], [serial-tests])" \
+		> m4/libuv-extra-automake-flags.m4 || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		cc_cv_cflags__g=no
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	mkdir "${BUILD_DIR}"/test || die
+	cp -pPR "${S}"/test/fixtures "${BUILD_DIR}"/test/fixtures || die
+	default
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}