1 files changed, 47 insertions, 0 deletions
diff --git a/dev-libs/libev/libev-4.15-r1.ebuild b/dev-libs/libev/libev-4.15-r1.ebuild
new file mode 100644
index 000000000000..105241cf1e88
--- /dev/null
+++ b/dev-libs/libev/libev-4.15-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="A high-performance event loop/event model with lots of feature"
+HOMEPAGE="http://software.schmorp.de/pkg/libev.html"
+SRC_URI="http://dist.schmorp.de/libev/${P}.tar.gz
+	http://dist.schmorp.de/libev/Attic/${P}.tar.gz"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="elibc_glibc static-libs"
+
+# Bug #283558
+DEPEND="elibc_glibc? ( >=sys-libs/glibc-2.9_p20081201 )"
+RDEPEND="${DEPEND}"
+
+DOCS=( Changes README )
+
+src_prepare() {
+	sed -i -e "/^include_HEADERS/s/ event.h//" Makefile.am || die
+
+	# bug #411847
+	epatch "${FILESDIR}/${PN}-pc.patch"
+	# bug #493050
+	epatch "${FILESDIR}/${P}-automake-1.14.patch"
+
+	epatch_user
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		--disable-maintainer-mode \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	use static-libs || prune_libtool_files
+	einstalldocs
+}