1 files changed, 43 insertions, 0 deletions
diff --git a/app-i18n/libhangul/libhangul-0.1.0-r1.ebuild b/app-i18n/libhangul/libhangul-0.1.0-r1.ebuild
new file mode 100644
index 000000000000..5e8906a50a01
--- /dev/null
+++ b/app-i18n/libhangul/libhangul-0.1.0-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2006-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit libtool
+
+DESCRIPTION="Library for hangul input method logic, hanja dictionary"
+HOMEPAGE="https://github.com/libhangul/libhangul"
+SRC_URI="https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="nls static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+RDEPEND="virtual/libiconv
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )"
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable static-libs static)
+}
+
+src_test() {
+	emake -C test check
+}
+
+src_install() {
+	default
+	find "${ED}" -name "*.la" -delete || die
+}