2 files changed, 73 insertions, 0 deletions
diff --git a/app-crypt/swtpm/Manifest b/app-crypt/swtpm/Manifest
index c3415f424e07..596f1e10b4c8 100644
--- a/app-crypt/swtpm/Manifest
+++ b/app-crypt/swtpm/Manifest
@@ -1 +1,2 @@
 DIST swtpm-0.2.0.tar.gz 297419 BLAKE2B 9045cfd127d2f7e8e2e202818a375b4f6398806a097ed0df73abb76426db3af65a0d27f5e7212ce099d796862d3a9b3d421e987cf159bdce8879fc764eb5e923 SHA512 bda54690c0438138ff7adcc212fb125d2bb62618b10305eeced776e014bb135ea1a1dd1271a99fb2c60bf7e418644ded029c3c09ec2c6c1258e5062122cacf19
+DIST swtpm-0.3.0.tar.gz 308472 BLAKE2B c6b93303c77cb3de0917b219b7e8e216864a11cd7c584d85409b457bc36db9b0515639ae972f8ef39ba60f52506075a2cc697519bd18da9fdb12031e716c9e6e SHA512 e1e62367966224b3fc6edb80a883c5e3d6a698f437032e0b4b71558ebd7e24e5b92e7d843ee15ca29edd96710bbac51cb435956ac535b10a5f2b2afd65e748a3
diff --git a/app-crypt/swtpm/swtpm-0.3.0.ebuild b/app-crypt/swtpm/swtpm-0.3.0.ebuild
new file mode 100644
index 000000000000..eeb7c5075a97
--- /dev/null
+++ b/app-crypt/swtpm/swtpm-0.3.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="Libtpms-based TPM emulator"
+HOMEPAGE="https://github.com/stefanberger/swtpm"
+SRC_URI="https://github.com/stefanberger/swtpm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="fuse gnutls libressl seccomp test"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	fuse? (
+		dev-libs/glib:2
+		sys-fs/fuse:0
+	      )
+	gnutls? (
+		   dev-libs/libtasn1:=
+		   >=net-libs/gnutls-3.1.0[tools]
+		)
+	!libressl? (
+		 dev-libs/openssl:0=
+		 dev-libs/libtpms[-libressl]
+		   )
+	libressl? (
+		    dev-libs/libressl:0=
+		    dev-libs/libtpms[libressl]
+		  )
+	seccomp? ( sys-libs/libseccomp )
+"
+
+DEPEND="${COMMON_DEPEND}
+	test? (
+		net-misc/socat
+		${PYTHON_DEPS}
+	      )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	app-crypt/tpm-tools
+	app-crypt/trousers
+	dev-tcltk/expect"
+
+src_prepare() {
+	use test || eapply "${FILESDIR}/${PN}-disable-test-dependencies.patch"
+	eapply "${FILESDIR}/${PN}-fix-localca-path.patch"
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+	  --with-openssl \
+	  --without-selinux \
+	  $(use_with fuse cuse) \
+	  $(use_with gnutls) \
+	  $(use_with seccomp)
+}
+
+src_install() {
+	default
+	fowners tss:tss /var/lib/swtpm-localca
+	keepdir /var/lib/swtpm-localca
+	find "${D}" -name '*.la' -delete || die
+}