1 files changed, 54 insertions, 0 deletions
diff --git a/app-crypt/keybase/keybase-2.6.0.ebuild b/app-crypt/keybase/keybase-2.6.0.ebuild
new file mode 100644
index 000000000000..af077ef41e52
--- /dev/null
+++ b/app-crypt/keybase/keybase-2.6.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-build systemd
+
+DESCRIPTION="Client for keybase.io"
+HOMEPAGE="https://keybase.io/"
+SRC_URI="https://github.com/keybase/client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	~app-crypt/kbfs-${PV}"
+RDEPEND="
+	app-crypt/gnupg"
+
+src_unpack() {
+	unpack "${P}.tar.gz"
+	ln -vs "client-${PV}" "${P}" || die
+	mkdir -vp "${S}/src/github.com/keybase" || die
+	ln -vs "${S}" "${S}/src/github.com/keybase/client" || die
+}
+
+src_compile() {
+	EGO_PN="github.com/keybase/client/go/keybase" \
+		EGO_BUILD_FLAGS="-tags production -o ${T}/keybase" \
+		golang-build_src_compile
+}
+
+src_test() {
+	EGO_PN="github.com/keybase/client/go/keybase" \
+		golang-build_src_test
+}
+
+src_install() {
+	dobin "${T}/keybase"
+	dobin "${S}/packaging/linux/run_keybase"
+	systemd_douserunit "${S}/packaging/linux/systemd/keybase.service"
+	dodir "/opt/keybase"
+	insinto "/opt/keybase"
+	doins "${S}/packaging/linux/crypto_squirrel.txt"
+}
+
+pkg_postinst() {
+	elog "Start/Restart keybase: run_keybase"
+	elog "Run the service:       keybase service"
+	elog "Run the client:        keybase login"
+	ewarn "Note that the user keybasehelper is obsolete and can be removed"
+}