1 files changed, 0 insertions, 85 deletions
diff --git a/app-containers/containerd/containerd-1.6.2.ebuild b/app-containers/containerd/containerd-1.6.2.ebuild
deleted file mode 100644
index eef31e9b8f79..000000000000
--- a/app-containers/containerd/containerd-1.6.2.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-GIT_REVISION=de8046a5501db9e0e478e1c10cbcfb21af4c6b2d
-inherit go-module systemd
-
-DESCRIPTION="A daemon to control runC"
-HOMEPAGE="https://containerd.io/"
-SRC_URI="https://github.com/containerd/containerd/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-SRC_URI+=" https://dev.gentoo.org/~williamh/dist/${P}-deps.tar.xz"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="apparmor btrfs device-mapper +cri hardened +seccomp selinux test"
-
-DEPEND="
-	btrfs? ( sys-fs/btrfs-progs )
-	seccomp? ( sys-libs/libseccomp )
-"
-
-# recommended version of runc is found in script/setup/runc-version
-RDEPEND="
-	${DEPEND}
-	~app-containers/runc-1.1.0
-"
-
-BDEPEND="
-	dev-go/go-md2man
-	virtual/pkgconfig
-"
-
-# tests require root or docker
-# upstream does not recommend stripping binary
-RESTRICT+=" strip test"
-
-src_prepare() {
-	default
-	sed -i \
-		-e "s/-s -w//" \
-		Makefile || die
-	sed -i \
-		-e "s:/usr/local:/usr:" \
-		containerd.service || die
-}
-
-src_compile() {
-	local options=(
-		$(usev apparmor)
-		$(usex btrfs "" "no_btrfs")
-		$(usex cri "" "no_cri")
-		$(usex device-mapper "" "no_devmapper")
-		$(usev seccomp)
-		$(usev selinux)
-	)
-
-	myemakeargs=(
-		BUILDTAGS="${options[*]}"
-		LDFLAGS="$(usex hardened '-extldflags -fno-PIC' '')"
-		REVISION="${GIT_REVISION}"
-		VERSION=v${PV}
-	)
-
-	# race condition in man target https://bugs.gentoo.org/765100
-	# we need to explicitly specify GOFLAGS for "go run" to use vendor source
-	emake "${myemakeargs[@]}" man -j1 #nowarn
-	emake "${myemakeargs[@]}" all
-
-}
-
-src_install() {
-	dobin bin/*
-	doman man/*
-	newinitd "${FILESDIR}"/${PN}.initd "${PN}"
-	systemd_dounit containerd.service
-	keepdir /var/lib/containerd
-
-	# we already installed manpages, remove markdown source
-	# before installing docs directory
-	rm -r docs/man || die
-
-	local DOCS=( ADOPTERS.md README.md RELEASES.md ROADMAP.md SCOPE.md docs/. )
-	einstalldocs
-}