xfce-extra/xfce4-screensaver: Bump to 0.1.11

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/xfce-extra/xfce4-screensaver/Manifest b/xfce-extra/xfce4-screensaver/Manifest
index 0036ec3831fb..084b804a8199 100644
--- a/xfce-extra/xfce4-screensaver/Manifest
+++ b/xfce-extra/xfce4-screensaver/Manifest
@@ -1 +1,2 @@
 DIST xfce4-screensaver-0.1.10.tar.bz2 665624 BLAKE2B 9af4a821bcbb461462cf620dbd2c064a32b904f0d6887095cd00939f857244d69612e18559c0cf0be93e9044047d0e3dba8c756acc16fe9e3e136a718beb3942 SHA512 a04842697c7a8f84ee937f0371b3d1413163b59d1a54b9adf0b904dd501d6328ab645160567ff79afbe063cc113a488567ec5d8df4d6ed2db354738275c00b2e
+DIST xfce4-screensaver-0.1.11.tar.bz2 699642 BLAKE2B 5fbb5b5c923e82070e429fcf65c8c5b5b9b0d78cba9fd128c84490a6a0927a0620b41af7ffb7356cd13ccfe48f2e1841f90e980c4bfbd15fa8f50e0f1fed7e75 SHA512 f692e31cba00d65887b90857eb4c1075000859f85db7dac7f421cc0d9812c6e8d517fcdfcac7546a6818375f9a7222a2afb80ae7076e62953bc8dcc7af9be174
diff --git a/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.11.ebuild b/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.11.ebuild
new file mode 100644
index 000000000000..4b044eaf8700
--- /dev/null
+++ b/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.11.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Screen saver and locker (port of MATE screensaver)"
+HOMEPAGE="https://git.xfce.org/apps/xfce4-screensaver/about/"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="elogind +locking opengl pam systemd"
+
+# Xrandr: optional but automagic
+RDEPEND="
+	>=dev-libs/dbus-glib-0.30
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3
+	>=x11-libs/libwnck-3.20:3
+	x11-libs/libICE:=
+	x11-libs/libX11:=
+	x11-libs/libXScrnSaver:=
+	x11-libs/libXext:=
+	x11-libs/libXxf86vm:=
+	>=x11-libs/libXrandr-1.3:=
+	>=x11-libs/libxklavier-5.2:=
+	>=xfce-base/garcon-0.5.0:=
+	>=xfce-base/libxfce4ui-4.12.1:=
+	>=xfce-base/libxfce4util-4.12.1:=
+	>=xfce-base/xfconf-4.12.1:=
+	elogind? ( sys-auth/elogind )
+	locking? (
+		pam? ( sys-libs/pam )
+	)
+	opengl? ( virtual/opengl )
+	systemd? ( sys-apps/systemd:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-apps/dbus
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		# disable docbook for now
+		ac_cv_path_XMLTO=no
+
+		# xscreensaver dirs autodetection doesn't seem to work
+		--with-xscreensaverdir=/usr/share/xscreensaver/config
+		--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+		--without-console-kit
+
+		$(use_with opengl libgl)
+		$(use_enable locking)
+		$(use_enable pam)
+		$(use_with elogind)
+		$(use_with systemd)
+	)
+
+	if use pam; then
+		myconf+=( --with-pam-auth-type=system )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}