x11-wm/dwm: Drop pointless pkg_postinst() (bug #583136).

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 68 insertions, 0 deletions

diff --git a/x11-wm/dwm/dwm-6.1-r1.ebuild b/x11-wm/dwm/dwm-6.1-r1.ebuild
new file mode 100644
index 000000000000..e20c2af07b49
--- /dev/null
+++ b/x11-wm/dwm/dwm-6.1-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils savedconfig toolchain-funcs
+
+DESCRIPTION="a dynamic window manager for X11"
+HOMEPAGE="http://dwm.suckless.org/"
+SRC_URI="http://dl.suckless.org/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="xinerama"
+
+RDEPEND="
+	x11-libs/libX11
+	media-libs/freetype
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	xinerama? ( x11-proto/xineramaproto )
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s/CFLAGS = -std=c99 -pedantic -Wall -Os/CFLAGS += -std=c99 -pedantic -Wall/" \
+		-e "/^LDFLAGS/{s|=|+=|g;s|-s ||g}" \
+		-e "s/#XINERAMALIBS =/XINERAMALIBS ?=/" \
+		-e "s/#XINERAMAFLAGS =/XINERAMAFLAGS ?=/" \
+		-e "s@/usr/X11R6/include@${EPREFIX}/usr/include/X11@" \
+		-e "s@/usr/X11R6/lib@${EPREFIX}/usr/lib@" \
+		-e "s@-I/usr/include@@" -e "s@-L/usr/lib@@" \
+		-e "s/\/freetype2/\ -I\/usr\/include\/freetype2/" \
+		config.mk || die
+	sed -i \
+		-e '/@echo CC/d' \
+		-e 's|@${CC}|$(CC)|g' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	if use xinerama; then
+		emake CC=$(tc-getCC) dwm
+	else
+		emake CC=$(tc-getCC) XINERAMAFLAGS="" XINERAMALIBS="" dwm
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/dwm-session2 dwm
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}"/dwm.desktop
+
+	dodoc README
+
+	save_config config.h
+}