www-client/opera-developer: automated bump (85.0.4323.0)

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 158 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 72b7efd77b2d..78deb0e89ff4 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,4 +1,5 @@
 DIST opera-developer_84.0.4302.0_amd64.deb 84119048 BLAKE2B 02906fe4ea5e42de06442c3040e0d535260cbc354612ef0ebe5da0e5eae29cb0149ba9ef69bed20e794f2383b9278a543648f55f4973b5b924f40f146c2ca1ba SHA512 7368e9f1ba92b26a9ee4a057b2d51f8bc83a054402c86a93718ef0af37dc78462766e675e5ab957156e5e6722b83b41c00567d37672427a6b8af532520d0b61a
 DIST opera-developer_84.0.4309.0_amd64.deb 84155188 BLAKE2B 1d10be345cc69a1b2dac175df45b2100e206d03f2534d4a722d9a31c26f4e1783c86c787f00237b0c44f71072e99e1229d832a33f5e666c89377ddab92c1be9f SHA512 28e0b79450d105f10079cd89c648d13d0eb62399a9d1ead14c377a431851aa6b69dd5c81f6a7efbc02c0a2c841d6cc7731cc3a3cbdcd88db7d9457cdc80a6fec
 DIST opera-developer_84.0.4316.0_amd64.deb 84172660 BLAKE2B d54239d0640a1af6ca0f3e8780e25d3e962969c9cccd23688b72dd5fed960d9829c028840465e5b49cb8338e2f46ae5dea5f0e71d8bc9be30f3e5c6132303a12 SHA512 d44cb4984e99536d132d7a2f20899f03401ffbd5a563ff0fa80c4df2b9606150781f582bf6cafd4ffb9ea00e4ead43d955631c5eb25bfef04eecfce41655d5df
+DIST opera-developer_85.0.4323.0_amd64.deb 84158124 BLAKE2B d9eec8879b9ff98d23444a0465016e10a2437d7167c77abd635ab0aa7d004ec61331b6cf08573d80de93e91dc9a063d397fcd4e0f649d32889fccf4a6e8dbaf7 SHA512 9590502503fc900d2f7137e16ecf7879cba8016b8f85ddd872fd0799ad304cd0a06a1d2d7ca43f6461de449a0ab2a32cf3822623b583a770f0066fce58daf390
 DIST opera-ffmpeg-codecs-96.0.4655.7.tar.xz 1394152 BLAKE2B a48c1f22b5e92e40d8d5f97f02505021824823796767c1725c821b171b3ff6bf281d0123bf0b7e336f4d81b84bbf9362c6489f30b7de7c2037238c53003d6e00 SHA512 7c6815936e9a027d278a893e90e30f28a3d011ec83723c6500bee7ba0dddc5c96ae3cd75d7e16f7bbd2f9ee635fb64bdba6c2ba1df32761a6215be6eb3d5ec5c
diff --git a/www-client/opera-developer/opera-developer-85.0.4323.0.ebuild b/www-client/opera-developer/opera-developer-85.0.4323.0.ebuild
new file mode 100644
index 000000000000..eb20d71f86a9
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-85.0.4323.0.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="96.0.4655.7"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}