www-apps/jellyfin: add 10.8.11

Signed-off-by: Craig Andrews <candrews@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/www-apps/jellyfin/Manifest b/www-apps/jellyfin/Manifest
index 3d5ee5e16254..cdc4d481b09b 100644
--- a/www-apps/jellyfin/Manifest
+++ b/www-apps/jellyfin/Manifest
@@ -1,2 +1,4 @@
 DIST jellyfin_10.8.10_amd64.tar.gz 99073643 BLAKE2B 044373d249644684fd8eaa3d1031b7ffcb90a45b5a90a8abb949604660befdcf084d1675c121a41119c5ebe1b440e4e913c74be6f28be5d15855da5b6e0f5090 SHA512 0574c9a20c72a241df06b9844496cab2419eeb467d928bb222ea5745ade2059648f0b8886a0264da8111e57e41b051ff437e4c4ff9af637277779f96f66e2c34
 DIST jellyfin_10.8.10_arm64.tar.gz 96002970 BLAKE2B 040a531b997dfc4ed5d6508e6913bce4c796e1be5e5b2e113f9e756ffd997a999e1df868929301c38d60c44a457a041316bc8d5bac32a8f5ba0e2b8908031da0 SHA512 3b2ca1587965a507f196f6508ebf3f703419a3aac0f9ee119997cef2cbe114d2d4b537475243263f15562cc84e2b41f337411ea38487f102548c80fbfa3131e5
+DIST jellyfin_10.8.11_amd64.tar.gz 99099022 BLAKE2B cde20d5b648aff4ad73eb1b18b8849f3decbe50b0cf88589f0f0d8c8b3e03efe74d46d76bcad4202e193cd8768e3226dff560c4388fecd1234a5ada60e68d2ba SHA512 d91914bfcee4cd51608c4df0d887e7711aff31414c006b5ea9ff4f65825069231faec1bfdeaa17074edaa6078c02fe93aacbdf387445fbaa45a2700abe2e251a
+DIST jellyfin_10.8.11_arm64.tar.gz 96033197 BLAKE2B 5b0ec331d157d1ff783aa010a4260b70b1c0cc62170549b4d926c197c51ead3b99375915753ab40ad90b4a8070db86ceeb200d30128f7e533cd33e365f10e80b SHA512 79bb2fd78b3f659b0e29d3a6a70eb8cdea768d01f1fdff4fa77f0e919e456b0bf441ba4d0bff0c40b34853690fd9530b3de5a361487b66e858b59c17438022c3
diff --git a/www-apps/jellyfin/jellyfin-10.8.11.ebuild b/www-apps/jellyfin/jellyfin-10.8.11.ebuild
new file mode 100644
index 000000000000..39218e469f00
--- /dev/null
+++ b/www-apps/jellyfin/jellyfin-10.8.11.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pax-utils systemd tmpfiles
+
+DESCRIPTION="Jellyfin puts you in control of managing and streaming your media"
+HOMEPAGE="https://jellyfin.readthedocs.io/en/latest/"
+
+SRC_URI="
+	arm64? (
+		https://repo.jellyfin.org/releases/server/linux/versions/stable/combined/${PV}/${PN}_${PV}_arm64.tar.gz
+		https://repo.jellyfin.org/archive/linux/stable/${PV}/combined/${PN}_${PV}_arm64.tar.gz
+	)
+	amd64? (
+		https://repo.jellyfin.org/releases/server/linux/versions/stable/combined/${PV}/${PN}_${PV}_amd64.tar.gz
+		https://repo.jellyfin.org/archive/linux/stable/${PV}/combined/${PN}_${PV}_amd64.tar.gz
+	)"
+
+RESTRICT="mirror test"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+DEPEND="acct-user/jellyfin
+	media-libs/fontconfig
+	sys-libs/zlib"
+RDEPEND="${DEPEND}
+	dev-libs/icu
+	media-video/ffmpeg[vpx,x264]
+	sys-libs/glibc"
+BDEPEND="acct-user/jellyfin"
+INST_DIR="/opt/${PN}"
+QA_PREBUILT="${INST_DIR#/}/*.so ${INST_DIR#/}/jellyfin ${INST_DIR#/}/createdump"
+
+src_unpack() {
+	unpack ${A}
+	mv ${PN}_${PV} ${P} || die
+}
+
+src_prepare() {
+	default
+
+	# https://github.com/jellyfin/jellyfin/issues/7471
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	keepdir /var/log/jellyfin
+	fowners jellyfin:jellyfin /var/log/jellyfin
+	keepdir /etc/jellyfin
+	fowners jellyfin:jellyfin /etc/jellyfin
+	insinto ${INST_DIR}
+	dodir ${INST_DIR}
+	doins -r "${S}"/*
+	newtmpfiles - jellyfin.conf <<<"d /var/cache/jellyfin 0775 jellyfin jellyfin -"
+	chmod 755 "${D}${INST_DIR}/jellyfin"
+	newinitd "${FILESDIR}/${PN}.init-r1" "${PN}"
+	newconfd "${FILESDIR}"/${PN}.confd "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	pax-mark -m "${ED}${INST_DIR}/jellyfin"
+}
+
+pkg_postinst() {
+	tmpfiles_process jellyfin.conf
+}