sys-kernel/gentoo-kernel-bin: bump to 5.4.104 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 5fa357c71aae..7f4282757b48 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -63,6 +63,7 @@ DIST gentoo-kernel-5.4.103-1.amd64.xpak 61177997 BLAKE2B 712b8043fb592f2cc80e3b2
 DIST gentoo-kernel-5.4.103-1.arm64.xpak 56419864 BLAKE2B e7044dd04d0f520911c1e7eba7ceb7519d5eafeb62ed51792e49198f44f8ca583253870e8b4849ae24268c44b0323e8d29a511041cdcf90d41b88b397e91281f SHA512 da0f93c078a1151edf07fda5efbcd10e853ccbc543ff16cd7b47fa815e4fac331b9fb69485ee26fafcbd5e007c4546267f630fb1e1d7bfff7afc559088dab0ed
 DIST gentoo-kernel-5.4.103-1.x86.xpak 52986552 BLAKE2B 49445d908dbbf0d0d9f6ca7550c5252e4ab27e7324a9191d603f410ac5bc85f5d38402fee0fc2182b3fdbc6cef6e446856261b0ce66a28d592a697f339a8b70f SHA512 f044ef8e43c3d0a392024cc7dbda1d21c68be686904b7284086adfb3c72c198b3e92491cebe9f8f9470843336047ab15328cc8602f0650fac180300ff87a4b19
 DIST gentoo-kernel-5.4.104-1.amd64.xpak 61168729 BLAKE2B f4035929ec0ae6f975b6a1f3c1e45349a34947447c12b0115f28b74087365d6933e0475da842adfc2e4f35cb198553a01aa422868a4ff7253340419485bf003b SHA512 d767213d45440be207896e46ca6dd9d21afb9847f8d7d40553ad6765d0e7a7d1d5d24ea6afc423bc90d9e27caed4c499ce77d8588a003d60be63b079b5982198
+DIST gentoo-kernel-5.4.104-1.arm64.xpak 56426355 BLAKE2B bf76ddf35a3a1406299161ac32fdf233ed87273e840d4c3c72e0fff0769f7e6706bc38ea9fb0aff3ae728343cf3586c337862ef625034ff3572ddb4616f148ce SHA512 98cd8c677f763b41517a09e5d5d2fbbf18b8a30deb1ab0b4821f4486edcf29ad46c29a1caad34f1218a97a1fa60cdf7ac06614a7c5c47669d0209f6bf76d46af
 DIST gentoo-kernel-5.4.104-1.x86.xpak 52994991 BLAKE2B e96911371fea462e94128a7790b089a5e1357b74b30d9b649097c7b295d8534195f4f98579a07f151e068d0a05d92cd181ab824cea181cd927457d36c8f84a6c SHA512 0715b8858ffd473bc694ae0f8ff79eae13d6849226424d56d5c20657116732d49571ac9b5434674c8db3e5765761f3f03372e1d5decb15ed723b42053888a0e8
 DIST gentoo-kernel-5.4.94-1.amd64.xpak 61075025 BLAKE2B 96f7d69735dacd618266d4220907d2e196d4a59f39fdb6c93e88299ecd26a503684bcfbe0a0dcc8c027c3e1b90fc7c066f0d0cb5e007efee859215c6a4b91807 SHA512 e786c30e4ac3e62f25cb6403105847c20b7673f0e9fee32f513854c6e739cce513409f136da9dfd8c366d74ffc4db00625dc5d6270623af56149e4dd05801c57
 DIST gentoo-kernel-5.4.94-1.arm64.xpak 56309818 BLAKE2B 50f9f4d7bfaee560860899a0a16805c0a805a9cd0b915a0dec3f654180db73cc73f3247ccc808842103fefabe9cbc0aa963aff8c649c0fe2d314a6ddf22a02ce SHA512 36ee8c73e76ac00ea6c26a5530d6dab91df46fcf2b5f072bbcc44d8bf8b7df710fa601584ee2707cb1c1bbfad9342e369a00926224a0527f1fd4588d01085508
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.104-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.104-r1.ebuild
new file mode 100644
index 000000000000..18c02d4c0f39
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.104-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}