sys-kernel/gentoo-kernel: Bump to 5.15.175

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 138 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel/Manifest b/sys-kernel/gentoo-kernel/Manifest
index 6d87330b4581..b569f8e8827b 100644
--- a/sys-kernel/gentoo-kernel/Manifest
+++ b/sys-kernel/gentoo-kernel/Manifest
@@ -8,6 +8,8 @@ DIST genpatches-5.15-183.base.tar.xz 7657948 BLAKE2B f54aea57a40b7af56cfdf8a754d
 DIST genpatches-5.15-183.extras.tar.xz 4060 BLAKE2B 34c8c3466fabebc63d7dcff661305bd8fcf57c4b3404adf6bafeab5d602ca86aa5afb28385aab9e755df2d5a0f71adf72c11a7ba97f93d9698b9368f492afe23 SHA512 094c5a55bdad6eb5a7b4aaa24bf3d7aa1ddb8138078e9bedb225b0863c7a2572bc0824c844930adc20a0f2fdb53771f66382dcf0f3e54ff7825697b61e0fb1d8
 DIST genpatches-5.15-184.base.tar.xz 7799348 BLAKE2B ac6470d6e8e6908ccc7d2f22c7b61a20988a8774f9923cd7ffb9e3fd70ba75c9e515f553641de1a155c059f46cacc3f64c2b3f464b2e03243be2aeeda14bd638 SHA512 74973c07981492df289dda643c70c3b616e272a43d6098d5cd7d8a8be003b71d83f7f4b4ac4f1358da1147b9e75e9e1cb1487b0e7d2d00b14a630836de616562
 DIST genpatches-5.15-184.extras.tar.xz 4056 BLAKE2B d78a2b6c176a91a0eb33f7b8dd7bfe286e6aabde27cee8f591574ec6392763b1db9b15c062f8acf46d3a9aaf4b442f43fdc83ed2f8dadc008146e7d72827c531 SHA512 ebc2c8e2cb4e341e28eb2e8a522ea0680f786a232b84d8bad4027dea9bf977f8d3f81b1af6c2d68747288c0b30b0bef08330e0a6417e5ae8cfdba0215dc554d0
+DIST genpatches-5.15-185.base.tar.xz 7813568 BLAKE2B a287174103461737a4af5e24410266140ecd2970dd5568557ea1270d7b3d9db98ee218c392a4e8ef35fadedcfb8f9013f6dd830c08c0d9b2147c57658720e1d4 SHA512 edec855e548f4ce61e2aa3e8a86216a75d43405141054c114f7f2ed024f91500b905e953dc07f528d19bd25b13781377d8c60ae70e0bb15330f5cd187762b509
+DIST genpatches-5.15-185.extras.tar.xz 4056 BLAKE2B bab13e1f8b400270ab36e78525947b68468504433f41784c507e6700d23e08b7eff91cd49e50398f90622cc289d6c4c122b3d5f8da77742b01c167ced5284cf2 SHA512 be561334e77afb45e11fe5e8c6c3b61d85c821776bcefc0cbe0d9addc6561a4c0bfc3956a990fa50f703d7defbc4a847ddeeb170d4dc828c2bcbd1a4c6f4429f
 DIST genpatches-6.1-128.base.tar.xz 6459108 BLAKE2B f27a537be69a26717ac1e251d7530b97f5f4498a088d80cfccc343b4d50bc7404e59ae9285bc06e4991e166121d52b8a84054ef8b8f707f242626a49ac202a5b SHA512 53277c695af046fd4f8c6362141317270022a4c18764b3563b47375f08f775644dec0929086108c5ddb1f8de8bdf8bdc244084fe0ea4a93fad1677013ea1c42c
 DIST genpatches-6.1-128.extras.tar.xz 4060 BLAKE2B a4f0e9f0b87dfaad00ff0b702b85c6e78c9543bd45887d6f8c550e487f60c744b2912374e972f1bdcff8de6a434d09dd0550579171764afd9a5c741a4468d743 SHA512 b20dfc8580a640d0c9ea07b7b21b38e9632df4705b3a5ae9cfd7d7cad0554b3159ca6cea91280e2a6232d2a2e26bc485bc23616c23e24bb87c5dcd60f8325558
 DIST genpatches-6.1-129.base.tar.xz 6480240 BLAKE2B 4b33131d21859d29c47c54913e878bdb2e1bc5b8f8333a016690a2153d13a14d49af1b0130bd1a9be64dd9accfb042f5284eb7a9c85c83b2cc661ba5e1c21777 SHA512 4884c72ee2037ee0f7edb9f59de6ea3f6650edc1ce514544da542310029bb95560c38e3ec1f86197109946fce445f150a022b620ee6adf55601bc0b897a928e0
diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-5.15.175.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-5.15.175.ebuild
new file mode 100644
index 000000000000..e38fbdb5532e
--- /dev/null
+++ b/sys-kernel/gentoo-kernel/gentoo-kernel-5.15.175.ebuild
@@ -0,0 +1,136 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit kernel-build toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 10 ))
+# https://koji.fedoraproject.org/koji/packageinfo?packageID=8
+# forked to https://github.com/projg2/fedora-kernel-config-for-gentoo
+CONFIG_VER=6.1.102-gentoo
+GENTOO_CONFIG_VER=g14
+
+DESCRIPTION="Linux kernel built with Gentoo patches"
+HOMEPAGE="
+	https://wiki.gentoo.org/wiki/Project:Distribution_Kernel
+	https://www.kernel.org/
+"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	https://github.com/projg2/gentoo-kernel-config/archive/${GENTOO_CONFIG_VER}.tar.gz
+		-> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz
+	amd64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-x86_64-fedora.config
+			-> kernel-x86_64-fedora.config.${CONFIG_VER}
+	)
+	arm64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-aarch64-fedora.config
+			-> kernel-aarch64-fedora.config.${CONFIG_VER}
+	)
+	ppc64? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-ppc64le-fedora.config
+			-> kernel-ppc64le-fedora.config.${CONFIG_VER}
+	)
+	x86? (
+		https://raw.githubusercontent.com/projg2/fedora-kernel-config-for-gentoo/${CONFIG_VER}/kernel-i686-fedora.config
+			-> kernel-i686-fedora.config.${CONFIG_VER}
+	)
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug hardened"
+REQUIRED_USE="
+	arm? ( savedconfig )
+	hppa? ( savedconfig )
+	sparc? ( savedconfig )
+"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel-bin:${SLOT}
+"
+BDEPEND="
+	debug? ( dev-util/pahole )
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+
+QA_FLAGS_IGNORED="
+	usr/src/linux-.*/scripts/gcc-plugins/.*.so
+	usr/src/linux-.*/vmlinux
+	usr/src/linux-.*/arch/powerpc/kernel/vdso.*/vdso.*.so.dbg
+"
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	default
+
+	local biendian=false
+
+	# prepare the default config
+	case ${ARCH} in
+		arm | hppa | sparc)
+			> .config || die
+		;;
+		amd64)
+			cp "${DISTDIR}/kernel-x86_64-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		arm64)
+			cp "${DISTDIR}/kernel-aarch64-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		ppc)
+			# assume powermac/powerbook defconfig
+			# we still package.use.force savedconfig
+			cp "${WORKDIR}/${MY_P}/arch/powerpc/configs/pmac32_defconfig" .config || die
+			;;
+		ppc64)
+			cp "${DISTDIR}/kernel-ppc64le-fedora.config.${CONFIG_VER}" .config || die
+			biendian=true
+			;;
+		x86)
+			cp "${DISTDIR}/kernel-i686-fedora.config.${CONFIG_VER}" .config || die
+			;;
+		*)
+			die "Unsupported arch ${ARCH}"
+			;;
+	esac
+
+	local myversion="-gentoo-dist"
+	use hardened && myversion+="-hardened"
+	echo "CONFIG_LOCALVERSION=\"${myversion}\"" > "${T}"/version.config || die
+	local dist_conf_path="${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"
+
+	local merge_configs=(
+		"${T}"/version.config
+		"${dist_conf_path}"/base.config
+	)
+	use debug || merge_configs+=(
+		"${dist_conf_path}"/no-debug.config
+	)
+	if use hardened; then
+		merge_configs+=( "${dist_conf_path}"/hardened-base.config )
+
+		tc-is-gcc && merge_configs+=( "${dist_conf_path}"/hardened-gcc-plugins.config )
+
+		if [[ -f "${dist_conf_path}/hardened-${ARCH}.config" ]]; then
+			merge_configs+=( "${dist_conf_path}/hardened-${ARCH}.config" )
+		fi
+	fi
+
+	# this covers ppc64 and aarch64_be only for now
+	if [[ ${biendian} == true && $(tc-endian) == big ]]; then
+		merge_configs+=( "${dist_conf_path}/big-endian.config" )
+	fi
+
+	kernel-build_merge_configs "${merge_configs[@]}"
+}