sys-cluster/kube-apiserver: 1.19.4 bump

Signed-off-by: William Hubbs <williamh@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/sys-cluster/kube-apiserver/kube-apiserver-1.19.4.ebuild b/sys-cluster/kube-apiserver/kube-apiserver-1.19.4.ebuild
new file mode 100644
index 000000000000..0c60e4a0143a
--- /dev/null
+++ b/sys-cluster/kube-apiserver/kube-apiserver-1.19.4.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit bash-completion-r1 go-module systemd
+
+DESCRIPTION="Kubernetes API server"
+HOMEPAGE="https://kubernetes.io"
+SRC_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="hardened"
+
+COMMON_DEPEND="
+	acct-group/kube-apiserver
+	acct-user/kube-apiserver"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}
+	!sys-cluster/kubernetes"
+BDEPEND=">=dev-lang/go-1.15"
+
+RESTRICT+=" test"
+S="${WORKDIR}/kubernetes-${PV}"
+
+src_compile() {
+	CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')" \
+		emake -j1 GOFLAGS=-v GOLDFLAGS="" LDFLAGS="" WHAT=cmd/${PN}
+}
+
+src_install() {
+	dobin _output/bin/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotated ${PN}
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+}