sys-cluster/cinder: 10.0.4 bup

Package-Manager: Portage-2.3.6, Repoman-2.3.3

3 files changed, 198 insertions, 4 deletions

diff --git a/sys-cluster/cinder/Manifest b/sys-cluster/cinder/Manifest
index f1605372814c..5cc880de2824 100644
--- a/sys-cluster/cinder/Manifest
+++ b/sys-cluster/cinder/Manifest
@@ -1,4 +1,5 @@
 DIST cinder-10.0.3.tar.gz 4620868 SHA256 53e7538299e3c72c809112e85a065581b38e752ec19a0dbc0c918554eedd6789 SHA512 e22fca956c751a70e2248cab42cca4a0671d8a52537083dc97db4ba2279678f08e894cffba3e6f7c8b32f5313bdccd2af890948c463683ac64e4cf0a3313cc3b WHIRLPOOL b904908c13ade48db737f2491c5afd864ac77fce5f249b8a66b60cde51573b3b43475d0292d6e99509f95f681a347225572944a5eb5451498e2e31fc01fa24f5
+DIST cinder-10.0.4.tar.gz 4625299 SHA256 3e318f87b5d4ac24709c313cea6beb33a1994e6cbf256192dad39f4aa3310219 SHA512 ee66e70f6e002f0186aa7fd5980926f14bee50a7949267e2130285e242c39808b059f6789e2d1ba91930bbe76ddd0c9e16d041212f277e283383b3ce83b31d4f WHIRLPOOL 015b7a3a7af746eb6182332fbe4e757d3c0d8f2c62a5ec62a29cda10cb32ace941266598d759d033362fc3c98d00b1780d4ebc6bb984190cc8ed73ca47e2308b
 DIST cinder-9.1.4.tar.gz 4195597 SHA256 ee8a2ca264a41c8f4ed48094722d683cffae99cee910f19a140b0d1d0f5251a4 SHA512 8039d5208296ea54fc869fb05dd91451ac3575eb3dd2ed97d0c63120d18b67b02b835a849cd1ec3dae349920895e13665c15a6daa53f67138823053c49ab87a9 WHIRLPOOL f2fd2bbba72d2f74f1395f2b280ed3304ecec37c9bcdc7b73a104d19698dad123ffdbce58249c426245c68584eb7a10a640f38a9192933d8db30a7f45b79c48e
 DIST newton-cinder-policy.json 6412 SHA256 3a140134201452c52a97eae9f4c45ea30a3a21cc7a30ee619ed37ab0723b6479 SHA512 3473b5790487bd037d54e4a1a89bab9d145bc34d137d52da2b6b311d2dfee2344fec75c6c96bc518a3e0b175fbd6cde71fb546406c0ef835898e3c1c88eb6d56 WHIRLPOOL f34dc729425fd82ddd9905c675fca9b765b4535dc87ec9d94acd1781c331e466f8688aace4954532e376e704cf3f1c8f4103f22e6838d4403c10311358e1ed2b
 DIST newton-cinder-volume.filters 11025 SHA256 c36bdb9abb4d97350db9971dae1c44a713911920362a0c6c5bc3cfe2701dd4f6 SHA512 311a636180a18bb45867d55f9d33f1eff053cc7b278b41149c58a14450ff8e6d2016d749cc3fb81d1976c4ab78f7701a908bd9c81eb6e9da31c20820a4eaff3d WHIRLPOOL 7496fffec8e42eb1c3bea39563cef8d48cb607b7de1ba8a4ac9a831b6def3dcbcfdf7d485aa81f52aa9bdf7600a51ba07ff85fbf88c5c70091ad88f8c01ca37e
diff --git a/sys-cluster/cinder/cinder-10.0.4.ebuild b/sys-cluster/cinder/cinder-10.0.4.ebuild
new file mode 100644
index 000000000000..9fd3fca29fb8
--- /dev/null
+++ b/sys-cluster/cinder/cinder-10.0.4.ebuild
@@ -0,0 +1,193 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1 eutils linux-info user
+
+DESCRIPTION="Cinder is the OpenStack Block storage service, a spin out of nova-volumes"
+HOMEPAGE="https://launchpad.net/cinder"
+SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/ocata/cinder.conf.sample -> ocata-cinder.conf.sample
+https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/ocata/policy.json -> ocata-cinder-policy.json
+https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/ocata/volume.filters -> ocata-cinder-volume.filters
+https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+api +scheduler +volume infiniband iscsi lvm mysql +memcached postgres rdma sqlite +tcp test +tgt"
+REQUIRED_USE="|| ( mysql postgres sqlite ) iscsi? ( tgt ) infiniband? ( rdma )"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	app-admin/sudo"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	dev-python/enum34[$(python_gen_usedep 'python2_7')]
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	!~dev-python/lxml-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-3.14.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.15.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.11.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-5.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-privsep-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-reports-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.0[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-barbicanclient-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-glanceclient-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-6.0.0[${PYTHON_USEDEP}]
+	!~dev-python/python-novaclient-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-swiftclient-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.10.0[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.12.2[${PYTHON_USEDEP}]
+	>=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+	!~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	!~dev-python/routes-2.3[${PYTHON_USEDEP}]
+	>=dev-python/taskflow-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/rtslib-fb-2.1.43[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.60[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.61[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		>=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+		!~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		>=dev-python/psycopg-2.5.0
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	>=dev-python/sqlalchemy-migrate-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.17.1[${PYTHON_USEDEP}]
+	~dev-python/suds-0.6[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-vmware-2.17.0[${PYTHON_USEDEP}]
+	>=dev-python/os-brick-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/os-win-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tooz-1.47.0[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.4.2[${PYTHON_USEDEP}]
+	>=dev-python/castellan-0.4.0[${PYTHON_USEDEP}]
+	iscsi? (
+		tgt? ( sys-block/tgt )
+		sys-block/open-iscsi
+	)
+	lvm? ( sys-fs/lvm2 )
+	memcached? ( net-misc/memcached )
+	app-emulation/qemu
+	sys-fs/sysfsutils"
+# qemu is needed for image conversion
+
+#PATCHES=(
+#)
+
+pkg_pretend() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES=""
+	if use tcp; then
+		CONFIG_CHECK_MODULES+="SCSI_ISCSI_ATTRS ISCSI_TCP "
+	fi
+	if use rdma; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_ISER "
+	fi
+	if use infiniband; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_IPOIB INFINIBAND_USER_MAD INFINIBAND_USER_ACCESS"
+	fi
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled"
+		done
+	fi
+}
+
+pkg_setup() {
+	enewgroup cinder
+	enewuser cinder -1 -1 /var/lib/cinder cinder
+}
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Let's track progress of this # https://bugs.launchpad.net/swift/+bug/1249727
+	nosetests -I test_wsgi.py cinder/tests/ || die "tests failed under python2.7"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	keepdir /etc/cinder
+	dodir /etc/cinder/rootwrap.d
+
+	for svc in api scheduler volume; do
+		newinitd "${FILESDIR}/cinder.initd" cinder-${svc}
+	done
+
+	insinto /etc/cinder
+	insopts -m0640 -o cinder -g cinder
+	doins "etc/cinder/api-httpd.conf"
+	doins "etc/cinder/logging_sample.conf"
+	doins "etc/cinder/rootwrap.conf"
+	doins "etc/cinder/api-paste.ini"
+	newins "${DISTDIR}/ocata-cinder-policy.json" "policy.json"
+	newins "${DISTDIR}/ocata-cinder.conf.sample" "cinder.conf.sample"
+	insinto /etc/cinder/rootwrap.d
+	newins "${DISTDIR}/ocata-cinder-volume.filters" "volume.filters"
+
+	dodir /var/log/cinder
+	fowners cinder:cinder /var/log/cinder
+
+	#add sudoers definitions for user nova
+	insinto /etc/sudoers.d/
+	insopts -m 0440 -o root -g root
+	newins "${FILESDIR}/cinder.sudoersd" cinder
+}
+
+pkg_postinst() {
+	if use iscsi ; then
+		elog "Cinder needs tgtd to be installed and running to work with iscsi"
+		elog "it also needs 'include /var/lib/cinder/volumes/*' in /etc/tgt/targets.conf"
+	fi
+}
diff --git a/sys-cluster/cinder/metadata.xml b/sys-cluster/cinder/metadata.xml
index 1ad12f6ac35b..997957ff34f4 100644
--- a/sys-cluster/cinder/metadata.xml
+++ b/sys-cluster/cinder/metadata.xml
@@ -7,17 +7,17 @@
   </maintainer>
   <longdescription lang="en">
     Cinder is the OpenStack Block storage service.
-	This is a spin out of nova-volumes.
+    This is a spin out of nova-volumes.
   </longdescription>
   <use>
     <flag name="api">Installs the initscripts for the cinder api service</flag>
     <flag name="iscsi">Allow using an iSCSI remote storage server as pool for disk image storage</flag>
     <flag name="lvm">Allow using the Logical Volume Manager (<pkg>sys-fs/lvm2</pkg>) as pool for disk image storage</flag>
     <flag name="memcached">Installs the memcached server</flag>
-		<flag name="rdma">Enable rdma storage backend support</flag>
+    <flag name="rdma">Enable rdma storage backend support</flag>
     <flag name="scheduler">Installs the initscripts for the cinder scheduler service</flag>
-		<flag name="tcp">Enables tcp support for the iscsi backend</flag>
-		<flag name="tgt">Enable tgt storage backend support</flag>
+    <flag name="tcp">Enables tcp support for the iscsi backend</flag>
+    <flag name="tgt">Enable tgt storage backend support</flag>
     <flag name="volume">Installs the initscripts for the cinder volume service</flag>
   </use>
   <upstream>