sys-apps/flatpak: Bump to version 1.10.6

Bug: https://bugs.gentoo.org/831087
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index c2d0e21e310a..c970a9f7b09b 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -1,2 +1,3 @@
 DIST flatpak-1.10.5.tar.xz 1511032 BLAKE2B 704ce0b5828728f1bb438dca2c1cd0b84277547fbb08400fe11abf243f5d9b5a6219c79188b362174f2a61eea42ae548d4279646838f3de3e4e75b8782f3dabe SHA512 8c2e365ce442a092c15178a8b39daecf21bfe162078c9a323e68d53194413f174e329812dd01d8da6bbfba3b0087aeb4d92a44067df3f6fa0253e33014d138ae
+DIST flatpak-1.10.6.tar.xz 1517800 BLAKE2B 517251ff75fe8f44ed5a7d2b69301ceb801265854c3570d5349da3e3bac0f4f416163226db0b518e3e2b67427ccb57f9e47b6ed5a6d8ea6a86af146e779a3525 SHA512 a6fd46eaaea8510c74671b365e633cd782a02ad05c54ff107226573e3333ae2e9bd9b2ed76dbed401383e784d9530079c80beebb9d8512738815a16cabbe278c
 DIST flatpak-1.12.2.tar.xz 1541068 BLAKE2B 78162c9ccf0b7b18e69c2594865999fc052a507b255b855f3879cdac0c86dbfcabc6a282f0a4de548d3e85142b0b3c8c26d21825f35e6a2f25ebc1aa13ff2b8b SHA512 4887fe540a821f2c8539fbe1fd89b1cc350126a6fa90c1acf070e08db0de1073406a061f5483bc7a7ef9b07f73409beb7bc02d055d4b3ae1c33ba5c318e11b6f
diff --git a/sys-apps/flatpak/flatpak-1.10.6.ebuild b/sys-apps/flatpak/flatpak-1.10.6.ebuild
new file mode 100644
index 000000000000..91ad5e3ebdae
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.10.6.ebuild
@@ -0,0 +1,102 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit autotools linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc gtk kde introspection policykit seccomp systemd"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	>=net-libs/libsoup-2.4:=
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	x11-apps/xauth
+	x11-libs/gdk-pixbuf:2=
+	x11-libs/libXau:=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+# pyparsing version pinned for https://bugs.gentoo.org/825230
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep '<dev-python/pyparsing-3.0.2[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--enable-xauth
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}