sys-apps/flatpak: add 1.12.7

Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index f5174fa5d270..f5e9fb98efb6 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -2,4 +2,5 @@ DIST flatpak-1.12.3.tar.xz 1555340 BLAKE2B 512b3f6abfb06d242aedad2c27c9870750254
 DIST flatpak-1.12.4.tar.xz 1556548 BLAKE2B 1347b4667b3b8e02309582c1819be7e052382bfca8f6bcdb8b578011e3931e18e8c358c9759b204c8c4f82ffe9f5157fda3c9c967cf1ad0bef2bfc39c4be2a8c SHA512 441c29c43dec6cb224f677e2d9b3dd09e95f4ca6e06d24ee30de1b931522502f903b0bbd3ead4886d16c25d8236a876ffb95ec907690aa7f55cd7ed31c5dd71b
 DIST flatpak-1.12.5.tar.xz 1557688 BLAKE2B d44b1f403afec1ce4896de70810b91eb2d5a81f923aecf5c52394aad7e5a07230ec73f14303dc3f2d201d9c0464ac268788608abb485295f56fdd5242d7cfce1 SHA512 3ac1832a3bca2544a685ba741fcb0762c615aa37600c5be6b4148ea3897800b6c2a39b81f389036896e1fe10d8fac903154917a2ae6e50b4a27a648c95acb46f
 DIST flatpak-1.12.6.tar.xz 1558800 BLAKE2B f029e5b638845758dd2a3694b6e2ecc9253163a5895c5f4aa483748626fb4202266de157d133f012b0f2b295962f423ad6025baffe424b43ac91bd48f509cacc SHA512 2ab9af100d04315df16ecff7a9f274caccfca0df831daf6abef01c7bd3f4aea2db50ca327d1782a69516b7002a8cf13951d4bdef867f5ffd09447e78357145d3
+DIST flatpak-1.12.7.tar.xz 1562920 BLAKE2B e0bd3fcf8e0bc329c237ba409f82d6bfad1734101068966c11f03c9e45302680f590162b04e2314b5ed93324e61b4c06c33496dba7ba59778c885f50dd00d9db SHA512 425f9d330c649de1079f3286cb6ad8cf7b6e5838921effa4fd6f51020b9bf7991ded9071566ec7032b9868ef3f7e14d1fb7c2be96f903e3af23a075592b78f50
 DIST flatpak-1.13.1.tar.xz 1626048 BLAKE2B 6dd02bd531a6d10d97ac94d744e7afc7c6a319fe576cd6e3ff882b41320f7ede5cf0d6d92dcf4287b19ae7d3e5ce6afeebd1ea0e517e566f5b218e05bdb2bc10 SHA512 7e0be34535d6e80a1d59bfc937b9a89c3b46acbbddd6a04583c4874a50539978bb493b5c08b083a5697615a3281346bf1770b681fbc27be682caf54ffdca937a
diff --git a/sys-apps/flatpak/flatpak-1.12.7.ebuild b/sys-apps/flatpak/flatpak-1.12.7.ebuild
new file mode 100644
index 000000000000..8a8e2987bc67
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.12.7.ebuild
@@ -0,0 +1,104 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc gtk kde introspection policykit seccomp systemd X"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	>=net-libs/libsoup-2.4:=
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	X? (
+		x11-apps/xauth
+		x11-libs/libXau:=
+	)
+	x11-libs/gdk-pixbuf:2=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+# pyparsing version pinned for https://bugs.gentoo.org/825230
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable X xauth)
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}