net-p2p/ktorrent: 23.08.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 95 insertions, 0 deletions

diff --git a/net-p2p/ktorrent/Manifest b/net-p2p/ktorrent/Manifest
index df3be0852840..f8a64625c63f 100644
--- a/net-p2p/ktorrent/Manifest
+++ b/net-p2p/ktorrent/Manifest
@@ -1,2 +1,3 @@
 DIST ktorrent-23.04.3.tar.xz 2150912 BLAKE2B a5dd4db22d68098192d4a7d8e3b6f8ce60ffb46de46a007ed05548031db1e8a2e31e987fc36ea1a09186e27c08985319336ae5ba90c7127fe4c9035881fb357b SHA512 a803ed8963184f15029e034de4e6e25945d26bd3903afe838eaf0f0f74b3ccb53f1b7732694bda443b8d6bae5ca91f27622334fc628a41002eed7f8e3459c0e5
 DIST ktorrent-23.08.3.tar.xz 2155780 BLAKE2B 7cf5d6106d94735f58794b459ff355035798c3969128b06a2b3372e7e65ea25312c6ac16167532a1bb80b79dfa7e22e9f25b2ad0089aa6ff8b263a18a4eec2c3 SHA512 c0ae1b1cbeb47d839a2fea8ce7976fb477d4215fad7212b0e3f4a9cedc830102e3386d76a4dbba6a93d39f2b84a0541b6e1a8a59073b580b8ed01c0b395cf89c
+DIST ktorrent-23.08.4.tar.xz 2155860 BLAKE2B 1adce89fce0eda0f96040912915848561cbb6a0792148c214fb843d7de72b65e5ea9d91f59e3aa9222be41efcea21f3d684e074150a56b609c8c6eec7918eb4c SHA512 e17e095e33ed84fecb2a0c9df920c74f74d009c4f17cf6efbc3db7fbb61213b16f061dd1d162a9a105bfe3a39e58d84d659fbf6f1286b07562d41f4b8186fe26
diff --git a/net-p2p/ktorrent/ktorrent-23.08.4.ebuild b/net-p2p/ktorrent/ktorrent-23.08.4.ebuild
new file mode 100644
index 000000000000..9f4200abafaf
--- /dev/null
+++ b/net-p2p/ktorrent/ktorrent-23.08.4.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="optional"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +logviewer +magnetgenerator
++mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=net-libs/libktorrent-${PVCUT}:5
+	infowidget? ( dev-libs/geoip )
+	ipfilter? ( >=kde-frameworks/karchive-${KFMIN}:5 )
+	mediaplayer? (
+		>=media-libs/phonon-4.11.0[qt5(+)]
+		>=media-libs/taglib-1.5
+	)
+	rss? (
+		>=dev-qt/qtwebengine-${QTMIN}:5
+		>=kde-frameworks/syndication-${KFMIN}:5
+	)
+	shutdown? ( kde-plasma/libkworkspace:5 )
+	stats? ( >=kde-frameworks/kplotting-${KFMIN}:5 )
+	upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+	zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	ipfilter? (
+		app-arch/bzip2
+		app-arch/unzip
+		kde-apps/kio-extras:5
+		>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	)
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
+		-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
+		-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
+		-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
+		-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
+		-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
+		-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
+		$(cmake_use_find_package rss KF5Syndication)
+		-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
+		-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
+		-DENABLE_STATS_PLUGIN=$(usex stats)
+		-DENABLE_UPNP_PLUGIN=$(usex upnp)
+		-DENABLE_SEARCH_PLUGIN=$(usex webengine)
+		-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
+	)
+# add back when ported
+# 		-DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
+	ecm_src_configure
+}