net-libs/tox: bump to 0.2.12

Also removed the warning about the broken
backawards compatible tox-bootstrap-daemon
files. Reenabled some tests that have been
fixed since the last version.

Signed-off-by: Josiah Mullins <JoMull01@protonmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 107 insertions, 0 deletions

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index c8133bf407bd..083981d3a3d2 100644
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1,2 +1,3 @@
 DIST c-toxcore-0.2.10.tar.gz 515842 BLAKE2B 8e79f9a5045b5fef7825e5eb21644625607d86e472ec75ff45ff826712efa515682f9439181d52444b2a6a21472c6e78a3bea5bb7e356373faf733e2644a315d SHA512 8a6a78c52a67be0b727d0d3a8d1cece20ad716a2e694df0aa747eee7764f64c957458584f59db5e727a9803ed7b21adc1ad8d7e80fd6651e7774ca3504b38fc7
 DIST c-toxcore-0.2.11.tar.gz 507476 BLAKE2B 67e86a5e5c8da1c387a319e6726eaccec28608f165f0b165d12e379cc7d8080baf9b89f438804ab8e59a8690a11bebba7f2ef689554800312fe039da77e70cac SHA512 616b30423a170463b4445f6940e038fd9af820946c970260fcf72cc54d08d2615364b9f086869180e3ae26154ea92fea6e9a602366306bc40c3e1575e86350df
+DIST c-toxcore-0.2.12.tar.gz 504832 BLAKE2B 625713142cc1e4b6583879144c05d47a40a1d98031a8a2bf0deec85a199f816a0ff6df5c76e9487a526d7c1c1650b37a10ed81be8233eaa1395707851378474f SHA512 c22f139cfff3a5aedf5fb08c33cae0dae3d6fbceec87867c81290e3bf9d2e13466a0e2bad8378a7a7ba1e9b7b9ad756712963461ae248102e4cab7d4691228d8
diff --git a/net-libs/tox/tox-0.2.12.ebuild b/net-libs/tox/tox-0.2.12.ebuild
new file mode 100644
index 000000000000..87c96ebdac87
--- /dev/null
+++ b/net-libs/tox/tox-0.2.12.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake systemd
+
+MY_P="c-toxcore-${PV}"
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat"
+SRC_URI="https://github.com/TokTok/c-toxcore/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/0.2"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+av daemon dht-node ipv6 log-debug +log-error log-info log-trace log-warn static-libs test"
+
+REQUIRED_USE="?? ( log-debug log-error log-info log-trace log-warn )
+		daemon? ( dht-node )"
+RESTRICT="!test? ( test )"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	>dev-libs/libsodium-0.6.1:=[asm,urandom,-minimal]
+	av? (
+		media-libs/libvpx
+		media-libs/opus
+	)
+	daemon? ( dev-libs/libconfig )"
+RDEPEND="
+	${DEPEND}
+	daemon? (
+		acct-group/tox
+		acct-user/tox
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	cmake_src_prepare
+	#remove faulty tests
+	for testname in lan_discovery save_compatibility; do
+		sed -i -e "/^auto_test(${testname})$/d" CMakeLists.txt || die
+	done
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DAUTOTEST=$(usex test)
+		-DBOOTSTRAP_DAEMON=$(usex daemon)
+		-DBUILD_MISC_TESTS=$(usex test)
+		-DBUILD_TOXAV=$(usex av)
+		-DDHT_BOOTSTRAP=$(usex dht-node)
+		-DENABLE_SHARED=ON
+		-DENABLE_STATIC=$(usex static-libs)
+		-DMUST_BUILD_TOXAV=$(usex av))
+	if use test; then
+		mycmakeargs+=(
+			-DTEST_TIMEOUT_SECONDS=120
+			-DUSE_IPV6=$(usex ipv6))
+	else
+		mycmakeargs+=(-DUSE_IPV6=OFF)
+	fi
+
+	if use log-trace; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="TRACE")
+	elif use log-debug; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="DEBUG")
+	elif use log-info; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="INFO")
+	elif use log-warn; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="WARNING")
+	elif use log-error; then
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="ERROR")
+	else
+		mycmakeargs+=(-DMIN_LOGGER_LEVEL="")
+		einfo "Logging disabled"
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use daemon; then
+		newinitd "${FILESDIR}"/initd tox-dht-daemon
+		newconfd "${FILESDIR}"/confd tox-dht-daemon
+		insinto /etc
+		doins "${FILESDIR}"/tox-bootstrapd.conf
+		systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+	fi
+}
+
+pkg_postinst() {
+	if use dht-node; then
+		ewarn "The QA notice regarding libmisc_tools.so is known by the upstream"
+		ewarn "developers and is on their TODO list. For more information,"
+		ewarn "please see 'https://github.com/toktok/c-toxcore/issues/1144'"
+		ewarn ""
+		ewarn "There is currently an unresolved issue with tox DHT Bootstrap node"
+		ewarn "that causes the program to be built with a null library reference."
+		ewarn "This causes an infinite loop for certain revdep-rebuild commands."
+		ewarn "If you aren't running a node, please consider disabling the dht-node use flag."
+	fi
+}