proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 55 insertions, 0 deletions

diff --git a/net-analyzer/libnasl/libnasl-2.2.9-r1.ebuild b/net-analyzer/libnasl/libnasl-2.2.9-r1.ebuild
new file mode 100644
index 000000000000..6f6f00f9ad53
--- /dev/null
+++ b/net-analyzer/libnasl/libnasl-2.2.9-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A remote security scanner for Linux (libnasl)"
+HOMEPAGE="http://www.nessus.org/"
+SRC_URI="ftp://ftp.nessus.org/pub/nessus/nessus-${PV}/src/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux"
+IUSE="static-libs"
+
+RDEPEND="
+	~net-analyzer/nessus-libraries-${PV}
+"
+DEPEND="
+	${RDEPEND}
+	sys-devel/bison
+"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-openssl-1.patch \
+		"${FILESDIR}"/${P}-gentoo.patch \
+		"${FILESDIR}"/${P}-bison3.patch
+
+	sed \
+		-e "/^LDFLAGS/s:$:${LDFLAGS}:g" \
+		-i nasl.tmpl.in || die
+
+	tc-export CC
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--enable-shared
+}
+
+src_compile() {
+	# emake fails for >= -j2. bug #16471.
+	emake -C nasl cflags
+	emake
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}