media-video/parole: Bump to 4.15.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/media-video/parole/Manifest b/media-video/parole/Manifest
index ec80573055d6..e760b45c864a 100644
--- a/media-video/parole/Manifest
+++ b/media-video/parole/Manifest
@@ -1 +1,2 @@
 DIST parole-1.0.5.tar.bz2 929983 BLAKE2B 542cee0e45b0f2219235211daf161984a50849cb864f00351c3f1c112b4a6cd11fdda4dd8b2fd6ebc0bf5984542135453bbf9180b458c6cfa76b740419806bfd SHA512 458b042752919d4dd1bfdaceda2b281b07a3094d986a99ec2ff51c12b7ca32adba6ce67ecb67e9ab70bdf83cfa22f8b5027054e2c3a3cf71d50ec8b98eeb24df
+DIST parole-4.15.0.tar.bz2 914253 BLAKE2B 5f783e62be640194be2872d3e38cbba90f093bb7a788efa82be8a05cb32b8e62d5b1df695b173c4b0c3a3738b3ce0dd642a589324a3bfeb418c5ebb76b81e1aa SHA512 456a88769b6fb13e8f34df6b0533a8271d1bd8291a1d90f57a3827a06a8c97d04f3ead5446cc55fd765d77d6f919cf5c15b8ddc7c7774f24e098333654b25b58
diff --git a/media-video/parole/parole-4.15.0.ebuild b/media-video/parole/parole-4.15.0.ebuild
new file mode 100644
index 000000000000..8eae0704c490
--- /dev/null
+++ b/media-video/parole/parole-4.15.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="A simple Xfce4 media player using GStreamer"
+HOMEPAGE="https://docs.xfce.org/apps/parole/start"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~x86"
+IUSE="libnotify taglib"
+
+DEPEND="
+	>=dev-libs/dbus-glib-0.100
+	>=dev-libs/glib-2.32:2
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	sys-apps/dbus
+	>=x11-libs/gtk+-3.20:3
+	x11-libs/libX11
+	>=xfce-base/libxfce4ui-4.11:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.11:=
+	>=xfce-base/xfconf-4.10:=
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	taglib? ( >=media-libs/taglib-1.6:0= )"
+RDEPEND="${DEPEND}
+	media-plugins/gst-plugins-meta:1.0"
+DEPEND+="
+	x11-base/xorg-proto"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		# clutter backend does not work with new GTK+3 versions
+		--disable-clutter
+		$(use_enable taglib)
+		$(use_enable libnotify notify-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}