media-sound/jack2: bump to 1.9.17 + eapi7 + updated live

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 113 insertions, 6 deletions

diff --git a/media-sound/jack2/Manifest b/media-sound/jack2/Manifest
index 4894fdb792d7..11a981e1df6a 100644
--- a/media-sound/jack2/Manifest
+++ b/media-sound/jack2/Manifest
@@ -1 +1,2 @@
 DIST jack2-1.9.16.tar.gz 974652 BLAKE2B ff20d57f544bd636d93e77c2c6dec3af3afbafe4a217ba480c66247ddb6d8ca60755fa55599240fdd75e8ce2c1f7d8fb4f1bf68de8a212268588245f35731ead SHA512 8e4717cad097806a436e3a7b7977faa65987ca0fe59fd285014d6207899c62f9abbb79474170d0e5a6e82d0dbfe998c1310b13c4de8cd68cea0a6935ba579fd1
+DIST jack2-1.9.17.tar.gz 975827 BLAKE2B 7841f2714dd2fe72d7f5d72fd93a24a63b75143d81bed5166d8b2b29af4acc487157f78b26290aacb45fb2a2c82c18156d8fb45f49bda8780cb6938ae72ffedb SHA512 dff611273e23cea6fe258114c65e193f01dfa0366ddd4e6a026a3d676a32002ee744bc70085fb8568cb85395399072beec2c7f7eed8d9ec912332a2a56623521
diff --git a/media-sound/jack2/jack2-1.9.17.ebuild b/media-sound/jack2/jack2-1.9.17.ebuild
new file mode 100644
index 000000000000..f6ae56eff777
--- /dev/null
+++ b/media-sound/jack2/jack2-1.9.17.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+PYTHON_REQ_USE="threads(+)"
+inherit python-single-r1 waf-utils multilib-minimal
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="https://jackaudio.org/"
+
+if [[ "${PV}" = "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
+else
+	MY_PV="${PV/_rc/-RC}"
+	MY_P="${PN}-${MY_PV}"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/jackaudio/jack2/archive/v${MY_PV}/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam readline sndfile"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( classic dbus )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+DEPEND="${PYTHON_DEPS}
+	media-libs/libsamplerate
+	media-libs/libsndfile
+	sys-libs/readline:0=
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+	dbus? (
+		dev-libs/expat[${MULTILIB_USEDEP}]
+		sys-apps/dbus[${MULTILIB_USEDEP}]
+	)
+	ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
+	metadata? ( sys-libs/db:* )
+	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+RDEPEND="${DEPEND}
+	dbus? (
+		$(python_gen_cond_dep '
+			dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	pam? ( sys-auth/realtime-base )
+	!media-sound/jack-audio-connection-kit:0"
+
+DOCS=( AUTHORS.rst ChangeLog.rst README.rst README_NETJACK2 )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.9.14-fix-doc.patch"
+)
+
+src_prepare() {
+	default
+	python_fix_shebang waf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local mywafconfargs=(
+		--htmldir=/usr/share/doc/${PF}/html
+		$(usex dbus --dbus "")
+		$(usex classic --classic "")
+		--alsa=$(usex alsa yes no)
+		--celt=no
+		--db=$(usex metadata yes no)
+		--doxygen=$(multilib_native_usex doc yes no)
+		--firewire=$(usex ieee1394 yes no)
+		--iio=no
+		--opus=$(usex opus yes no)
+		--portaudio=no
+		--readline=$(multilib_native_usex readline yes no)
+		--samplerate=$(multilib_native_usex libsamplerate yes no)
+		--sndfile=$(multilib_native_usex sndfile yes no)
+		--winmme=no
+	)
+
+	waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+multilib_src_compile() {
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+}
+
+multilib_src_install() {
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+}
+
+multilib_src_install_all() {
+	python_fix_shebang "${ED}"
+}
diff --git a/media-sound/jack2/jack2-9999.ebuild b/media-sound/jack2/jack2-9999.ebuild
index f80759ad3794..f6ae56eff777 100644
--- a/media-sound/jack2/jack2-9999.ebuild
+++ b/media-sound/jack2/jack2-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 PYTHON_COMPAT=( python3_{6,7,8,9} )
 PYTHON_REQ_USE="threads(+)"
@@ -29,7 +29,11 @@ REQUIRED_USE="
 	${PYTHON_REQUIRED_USE}
 	|| ( classic dbus )"
 
-CDEPEND="${PYTHON_DEPS}
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+DEPEND="${PYTHON_DEPS}
 	media-libs/libsamplerate
 	media-libs/libsndfile
 	sys-libs/readline:0=
@@ -41,10 +45,7 @@ CDEPEND="${PYTHON_DEPS}
 	ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
 	metadata? ( sys-libs/db:* )
 	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
-DEPEND="${CDEPEND}
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )"
-RDEPEND="${CDEPEND}
+RDEPEND="${DEPEND}
 	dbus? (
 		$(python_gen_cond_dep '
 			dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
@@ -55,6 +56,10 @@ RDEPEND="${CDEPEND}
 
 DOCS=( AUTHORS.rst ChangeLog.rst README.rst README_NETJACK2 )
 
+PATCHES=(
+	"${FILESDIR}/${PN}-1.9.14-fix-doc.patch"
+)
+
 src_prepare() {
 	default
 	python_fix_shebang waf