media-sound/gigedit: bump to 1.2.0 + sync'd live

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 63 insertions, 24 deletions

diff --git a/media-sound/gigedit/Manifest b/media-sound/gigedit/Manifest
index 792c3d0bc999..1ed128009f0a 100644
--- a/media-sound/gigedit/Manifest
+++ b/media-sound/gigedit/Manifest
@@ -1 +1,2 @@
 DIST gigedit-1.1.1.tar.bz2 1146369 BLAKE2B 3a8a42db746d9fdaf713ae29e238c6f0fddcf4f5c1542fe980fb26babd28707bd3831db4f0d9e8aa58621bf1c7e08113315893515e1f445c5be9600e4e1bef12 SHA512 223702628e83e12a292f902e32baa355aca31ee82f1f8b9fed586ec9c0aaec56956d7bdc958238ec64e79b2f4c5ef9246face669b2b3645046e51d8c8289a964
+DIST gigedit-1.2.0.tar.bz2 1174502 BLAKE2B 049e4c60b345c192255669a71588df1e2905590f95351d8a79134b210d03087ac9cc33f12cbf2e38208b95ad452f299c78877632989cd914d98a05c5967087d5 SHA512 b991a5193af34be70db6eb8c18fc58e01b822b6997bfc6c3ee06eca42f57375d341316e8abc594824668c7cb916b0643a1ee1b5c34426bf3ec5e202dfc565c8f
diff --git a/media-sound/gigedit/gigedit-1.2.0.ebuild b/media-sound/gigedit/gigedit-1.2.0.ebuild
new file mode 100644
index 000000000000..4d2a0ef9057a
--- /dev/null
+++ b/media-sound/gigedit/gigedit-1.2.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop flag-o-matic xdg
+
+DESCRIPTION="An instrument editor for gig files"
+HOMEPAGE="http://www.linuxsampler.org/"
+SRC_URI="http://download.linuxsampler.org/packages/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-cpp/gtkmm:2.4
+	media-libs/libgig
+	media-libs/libsndfile
+	media-sound/linuxsampler"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	# docdir is not propagated there
+	sed -i '/docdir/d' doc/quickstart/Makefile.am || die
+	# file missing in pot file
+	echo src/gigedit/ScriptPatchVars.cpp >> "po/POTFILES.in" || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -Wl,-rpath,"${EPREFIX}/usr/$(get_libdir)/linuxsampler"
+	econf --disable-static
+}
+
+src_install() {
+	default
+	make_desktop_entry gigedit GigEdit "" "AudioVideo;AudioVideoEditing"
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/media-sound/gigedit/gigedit-9999.ebuild b/media-sound/gigedit/gigedit-9999.ebuild
index 6aee05e17e9a..aaef3a74634e 100644
--- a/media-sound/gigedit/gigedit-9999.ebuild
+++ b/media-sound/gigedit/gigedit-9999.ebuild
@@ -2,7 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-inherit autotools desktop xdg subversion
+
+inherit autotools desktop flag-o-matic xdg subversion
 
 DESCRIPTION="An instrument editor for gig files"
 HOMEPAGE="http://www.linuxsampler.org/"
@@ -10,44 +11,35 @@ ESVN_REPO_URI="https://svn.linuxsampler.org/svn/gigedit/trunk"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
-IUSE=""
 
-BDEPEND="
-	sys-devel/gettext
-	>=dev-util/intltool-0.35.0
-	virtual/pkgconfig
-"
-CDEPEND="
+RDEPEND="
 	dev-cpp/gtkmm:2.4
-	>=media-libs/libgig-3.3.0
-	>=media-libs/libsndfile-1.0.2
-	>=media-sound/linuxsampler-0.5.1
-"
+	media-libs/libgig
+	media-libs/libsndfile
+	media-sound/linuxsampler"
 DEPEND="${RDEPEND}"
-RDEPEND="${CDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig"
 
 src_prepare() {
 	default
-
 	# docdir is not propagated there
-	sed -i "s%\$(datadir)/doc/\$(PACKAGE)%\$(datadir)/doc/${P}%g" doc/quickstart/Makefile.am || die
+	sed -i '/docdir/d' doc/quickstart/Makefile.am || die
+	# file missing in pot file
+	echo src/gigedit/ScriptPatchVars.cpp >> "po/POTFILES.in" || die
 	eautoreconf
 }
 
 src_configure() {
+	append-ldflags -Wl,-rpath,"${EPREFIX}/usr/$(get_libdir)/linuxsampler"
 	econf --disable-static
 }
 
-src_compile() {
-	emake LDFLAGS="${LDFLAGS} -Wl,-rpath,/usr/$(get_libdir)/linuxsampler"
-}
-
 src_install() {
 	default
-
-	einfo "Removing static libs..."
-	find "${D}" -name "*.la" -delete || die "Failed to remove static libs"
-
 	make_desktop_entry gigedit GigEdit "" "AudioVideo;AudioVideoEditing"
+
+	find "${ED}" -name '*.la' -delete || die
 }