media-sound/strawberry: removed obsolete 1.0.1-r1

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 0 insertions, 121 deletions

diff --git a/media-sound/strawberry/Manifest b/media-sound/strawberry/Manifest
index 4c360d62bf9e..e2311d6d9f88 100644
--- a/media-sound/strawberry/Manifest
+++ b/media-sound/strawberry/Manifest
@@ -1,3 +1,2 @@
-DIST strawberry-1.0.1.tar.xz 11191132 BLAKE2B e182ec5db26b22b60e9393b3a418cf44c01b647ab268bafe6d3f098d879817563d68faf7962f0670017f70b7f9f64f3a680056002e7041a2dc956fdc1dceeb95 SHA512 6a668ba6dbdcd5c60e78190c2cc8c04ad4ed920102c7555fdd42f6bf47c5b4004f9580c0f009cade642b404f6884b2b5dac386d326bf6f234403e4ba7612a2bb
 DIST strawberry-1.0.2.tar.xz 11202768 BLAKE2B 555c9492a6c10e9df579d4e9b1c718c722531f21784f68a436d8bd313a6950f0cfc58ded85f9a144de12a73ab07a0cc4d0e028223122dd4fde6604eb92145bd8 SHA512 196be23dde8fee531b2996bc7dacaf5b00dcd3f1aaaeb6630ed2a2fdeb777abb66d6c19928fc157dde7d5bceffdc646ff615a6d52bc0e6ee5ddcc14de6ee7a59
 DIST strawberry-1.0.3.tar.xz 11197224 BLAKE2B de47d07133506e21e5e5cc6a9460482f364cca4eb1ff9a3433b09a75db4cbde339b6ed7949d788c87d465b6dac488e598b4840a3b24d6439f28cbe59185b01e3 SHA512 a61c0824ac75d29048c31ce7d8b7ae5ccc700f21700951b53ab87f30b15a2ce49368c7a366037565d3b5c556cf20dad8c93d1db936108eda7429518d7700d6dc
diff --git a/media-sound/strawberry/strawberry-1.0.1-r1.ebuild b/media-sound/strawberry/strawberry-1.0.1-r1.ebuild
deleted file mode 100644
index 721ef2158d3d..000000000000
--- a/media-sound/strawberry/strawberry-1.0.1-r1.ebuild
+++ /dev/null
@@ -1,120 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic plocale xdg
-
-PLOCALES="ca cs de es es_AR es_ES es_MX fi fr hu id it ja ko nb nl pl pt_BR ru sv uk zh_CN"
-
-DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
-HOMEPAGE="https://www.strawberrymusicplayer.org/"
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/strawberrymusicplayer/strawberry"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/strawberrymusicplayer/strawberry/releases/download/${PV}/${P}.tar.xz"
-	KEYWORDS="amd64 ~ppc64 x86"
-fi
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="cdda debug +gstreamer ipod moodbar mtp pulseaudio +udisks vlc"
-
-BDEPEND="
-	dev-qt/linguist-tools:5
-	sys-devel/gettext
-	virtual/pkgconfig
-"
-COMMON_DEPEND="
-	dev-db/sqlite:=
-	dev-libs/glib:2
-	dev-libs/protobuf:=
-	dev-qt/qtconcurrent:5
-	dev-qt/qtcore:5
-	dev-qt/qtdbus:5
-	dev-qt/qtgui:5
-	dev-qt/qtnetwork:5[ssl]
-	dev-qt/qtsql:5[sqlite]
-	dev-qt/qtwidgets:5
-	dev-qt/qtx11extras:5
-	media-libs/alsa-lib
-	>=media-libs/taglib-1.11.1_p20181028
-	x11-libs/libX11
-	cdda? ( dev-libs/libcdio:= )
-	gstreamer? (
-		>=media-libs/chromaprint-1.4:=
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-	)
-	ipod? ( >=media-libs/libgpod-0.8.0 )
-	moodbar? ( sci-libs/fftw:3.0 )
-	mtp? ( >=media-libs/libmtp-1.0.0 )
-	pulseaudio? ( media-sound/pulseaudio )
-	vlc? ( media-video/vlc )
-"
-# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
-RDEPEND="${COMMON_DEPEND}
-	gstreamer? (
-		media-plugins/gst-plugins-meta:1.0
-		media-plugins/gst-plugins-soup:1.0
-		media-plugins/gst-plugins-taglib:1.0
-	)
-	mtp? ( gnome-base/gvfs[mtp] )
-	udisks? ( sys-fs/udisks:2 )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-cpp/gtest-1.8.0
-	dev-libs/boost
-	dev-qt/qttest:5
-"
-
-DOCS=( Changelog README.md )
-
-REQUIRED_USE="
-	cdda? ( gstreamer )
-	|| ( gstreamer vlc )
-"
-
-src_prepare() {
-	plocale_find_changes "src/translations" "" ".po"
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	# spotify is not in portage
-	local mycmakeargs=(
-		-DBUILD_WERROR=OFF
-		# avoid automagically enabling of ccache (bug #611010)
-		-DCCACHE_EXECUTABLE=OFF
-		-DENABLE_GIO=ON
-		-DLINGUAS="$(plocale_get_locales)"
-		-DENABLE_AUDIOCD="$(usex cdda)"
-		-DENABLE_GSTREAMER="$(usex gstreamer)"
-		-DENABLE_LIBGPOD="$(usex ipod)"
-		-DENABLE_LIBMTP="$(usex mtp)"
-		-DENABLE_LIBPULSE="$(usex pulseaudio)"
-		-DENABLE_MOODBAR="$(usex moodbar)"
-		-DENABLE_MUSICBRAINZ="$(usex gstreamer)"
-		-DENABLE_SONGFINGERPRINTING="$(usex gstreamer)"
-		-DENABLE_UDISKS2="$(usex udisks)"
-		-DENABLE_VLC="$(usex vlc)"
-		# Disable until we have qt6 in the tree
-		-DWITH_QT6=OFF
-	)
-
-	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
-
-	cmake_src_configure
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if use gstreamer ; then
-		elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
-		elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
-		elog "depending on your preferences"
-	fi
-}