media-sound/cava: add 0.8.1

Allows to drop the short lived maxed-bars patch,
no other real changes.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/media-sound/cava/Manifest b/media-sound/cava/Manifest
index 4e8b8b36d7cc..4499f91c3ec3 100644
--- a/media-sound/cava/Manifest
+++ b/media-sound/cava/Manifest
@@ -1 +1,2 @@
 DIST cava-0.8.0.tar.gz 99198 BLAKE2B e9b5c6697aef9e9a1a54bcb928933fbaad68be0ab27f91defdeadd39a0b38d278835c43ed16fd8757d6c57d36924551304e43b8721b7a31dcac3a586041dd0e4 SHA512 3072504592f2f2d5b525874eb9bd23fca4beed89425651104a82b8ea5c7e34abd38c4355d712f2c17bb489eb2c8c28a6914fd40a1b1003a9fcce9055290a9794
+DIST cava-0.8.1.tar.gz 99310 BLAKE2B e7d85a6241fee0a4e45f5c50d068b2300ee2d41a019738dc87317986525571eca5f56831e937580fecf949cc85e11512340678b5842ee6f2f3a99f9d06812c3a SHA512 fad4e4fefe98300cc2774a168322056e4181cd2a0cc77a8622471d86512bab9eea6c09559a75518785fbcafee5a958e6d95c8fe5ce1816253e4dec99a23fae1c
diff --git a/media-sound/cava/cava-0.8.1.ebuild b/media-sound/cava/cava-0.8.1.ebuild
new file mode 100644
index 000000000000..6bf3cc49a457
--- /dev/null
+++ b/media-sound/cava/cava-0.8.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Console-based Audio Visualizer for Alsa"
+HOMEPAGE="https://github.com/karlstav/cava/"
+SRC_URI="https://github.com/karlstav/cava/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa +ncurses portaudio pulseaudio sdl sndio"
+
+RDEPEND="
+	dev-libs/iniparser:4
+	sci-libs/fftw:=
+	alsa? ( media-libs/alsa-lib )
+	ncurses? ( sys-libs/ncurses:= )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl2[opengl,video] )
+	sndio? ( media-sound/sndio:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="app-editors/vim-core"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.0-gentoo-iniparser4.patch
+)
+
+src_prepare() {
+	default
+
+	# see autogen.sh
+	echo ${PV} > version || die
+	xxd -i example_files/config config_file.h || die
+
+	sed -i 's/-Werror //' Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable alsa input-alsa)
+		$(use_enable portaudio input-portaudio)
+		$(use_enable pulseaudio input-pulse)
+		$(use_enable sndio input-sndio)
+
+		$(use_enable ncurses output-ncurses)
+		$(use_enable sdl output-sdl)
+
+		GENTOO_SYSROOT="${ESYSROOT}" # see iniparser4.patch
+	)
+
+	econf "${econfargs[@]}"
+}
+
+pkg_postinst() {
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog "A default ~/.config/cava/config will be created after initial"
+		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
+		elog "for configuring audio input and more."
+	fi
+
+	if use !alsa && use !portaudio && use !pulseaudio && use !sndio; then
+		# give a warning given greets with a segfault without proper configuration
+		ewarn "All audio backends are disabled, ${PN} will only function if first"
+		ewarn "configured to use 'method = fifo' or 'shmem'."
+		ewarn "Tip: fifo is versatile, e.g. mkfifo fifo && jack_capture --daemon -ws > fifo"
+	fi
+}