media-sound/cantata: Version bump 2.0.1

Package-Manager: portage-2.3.0_rc1

2 files changed, 142 insertions, 0 deletions

diff --git a/media-sound/cantata/Manifest b/media-sound/cantata/Manifest
index 1f13682947f6..574a44a59929 100644
--- a/media-sound/cantata/Manifest
+++ b/media-sound/cantata/Manifest
@@ -1 +1,2 @@
 DIST cantata-2.0.0.tar.bz2 2147821 SHA256 6817611652e3e37a221e7b68fb41223b421ccc09688bfd718b1f5a2e34e81fa8 SHA512 53cb56411bc6c79692e97d39d8d8cbf5cbbe683fe0c32a8f1222e477deba0ff0e71f5daf0a49cc9c72cefb113278692193964a99ad008a6f9fc0f59304482ed0 WHIRLPOOL bffdc313a97e979f28be4ec28c2a06bf0406e6f23ccf7be2403d9167638d806f5f3e1d5f2e1ca1b376285b6d1586b955be5ba60dd546299d8ef5309ef0878c92
+DIST cantata-2.0.1.tar.bz2 2151126 SHA256 122bda13c0b4078b84640dabef444b37d705d71c6f95209a2d949acd28a0bbca SHA512 69ae0c67970ec43f407c5ad11c0ddf254060a16de5023b2fdaf14ad9637ad8be06101ebe6c5cb07283e058400b24d80177b89f10a7be486cdb994aed1ff5ba02 WHIRLPOOL 138fab5ebbe9418b2c2d37b5c479fa7118a4c567f9ecd2a1fe2f4f1ff53e78803ca1f0192c126940ab2409b13448631a6e96e4e1542255378ff2f237df46ea3c
diff --git a/media-sound/cantata/cantata-2.0.1.ebuild b/media-sound/cantata/cantata-2.0.1.ebuild
new file mode 100644
index 000000000000..e78b4488d910
--- /dev/null
+++ b/media-sound/cantata/cantata-2.0.1.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PLOCALES="cs de en_GB es fr hu ko pl ru zh_CN"
+inherit cmake-utils gnome2-utils l10n qmake-utils xdg
+
+DESCRIPTION="Featureful and configurable Qt client for the music player daemon (MPD)"
+HOMEPAGE="https://github.com/CDrummond/cantata"
+SRC_URI="https://github.com/CDrummond/cantata/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="cdda cddb http-server kde mtp musicbrainz qt5 replaygain taglib udisks"
+REQUIRED_USE="
+	cdda? ( udisks || ( cddb musicbrainz ) )
+	cddb? ( cdda taglib )
+	mtp? ( taglib udisks )
+	musicbrainz? ( cdda taglib )
+	qt5? ( !kde )
+	replaygain? ( taglib )
+"
+
+RDEPEND="
+	dev-db/sqlite:3
+	sys-libs/zlib
+	x11-libs/libX11
+	|| ( kde-frameworks/breeze-icons:5 kde-frameworks/oxygen-icons:* )
+	cdda? ( media-sound/cdparanoia )
+	cddb? ( media-libs/libcddb )
+	kde? ( kde-base/kdelibs:4 )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5 )
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsql:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	!qt5? (
+		dev-libs/qjson
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		dev-qt/qtsql:4
+		dev-qt/qtsvg:4
+	)
+	replaygain? (
+		media-libs/libebur128
+		media-sound/mpg123
+		virtual/ffmpeg
+	)
+	taglib? (
+		media-libs/taglib[asf,mp4]
+		media-libs/taglib-extras
+		!kde? ( udisks? ( sys-fs/udisks:2 ) )
+	)
+"
+DEPEND="${RDEPEND}
+	kde? ( sys-devel/gettext )
+	!kde? ( qt5? ( dev-qt/linguist-tools:5 ) )
+"
+
+# cantata has no tests
+RESTRICT="test"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# Unbundle 3rd party libs
+	rm -rf 3rdparty/qtsingleapplication/ || die
+	rm -rf 3rdparty/libebur128/ || die
+	# qjson ebuild does not support Qt5 yet
+	use qt5 || { rm -rf 3rdparty/qjson/ || die ;}
+	use kde && { rm -rf 3rdparty/solid-lite/ || die ;}
+
+	l10n_find_plocales_changes 'po' '' '.po'
+}
+
+src_configure() {
+	local langs="$(l10n_get_locales)"
+
+	local mycmakeargs=(
+		-DCANTATA_TRANSLATIONS="${langs// /;}"
+		-DENABLE_CDPARANOIA=$(usex cdda)
+		-DENABLE_CDDB=$(usex cddb)
+		-DENABLE_HTTP_SERVER=$(usex http-server)
+		-DENABLE_KDE=$(usex kde)
+		-DENABLE_MTP=$(usex mtp)
+		-DENABLE_MUSICBRAINZ=$(usex musicbrainz)
+		-DENABLE_QT5=$(usex qt5)
+		-DENABLE_FFMPEG=$(usex replaygain)
+		-DENABLE_MPG123=$(usex replaygain)
+		-DENABLE_TAGLIB=$(usex taglib)
+		-DENABLE_TAGLIB_EXTRAS=$(usex taglib)
+		-DENABLE_DEVICES_SUPPORT=$(usex udisks)
+		-DENABLE_HTTP_STREAM_PLAYBACK=OFF
+		-DENABLE_REMOTE_DEVICES=OFF
+		-DENABLE_UDISKS2=ON
+		-DUSE_SYSTEM_MENU_ICON=OFF
+	)
+
+	if ! use kde; then
+		if use qt5; then
+			mycmakeargs+=(
+				-DLCONVERT_EXECUTABLE="$(qt5_get_bindir)/lconvert"
+				-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
+			)
+		else
+			mycmakeargs+=(
+				-DLCONVERT_EXECUTABLE="$(qt4_get_bindir)/lconvert"
+				-DLRELEASE_EXECUTABLE="$(qt4_get_bindir)/lrelease"
+			)
+		fi
+	fi
+
+	cmake-utils_src_configure
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_pkg_postrm
+}