media-libs/aubio: Bump to 0.4.2.

Package-Manager: portage-2.2.23

2 files changed, 107 insertions, 0 deletions

diff --git a/media-libs/aubio/Manifest b/media-libs/aubio/Manifest
index d8ae92aa678f..81f462755119 100644
--- a/media-libs/aubio/Manifest
+++ b/media-libs/aubio/Manifest
@@ -1 +1,2 @@
 DIST aubio-0.4.1.tar.bz2 288136 SHA256 25d7df0a9cd6366fda764a803424caddf5fb819fc75b42a7a03e1e6f8eb3c695 SHA512 f36800f1a0cbe72509e05d15d79759ed25975e92701804597ed4c9d93e27d5e7b908e0aa65819ce763882945123ea174a0825c7aacf9f9494f56d72de5b8308c WHIRLPOOL ea410de8ca5d81c8b6ff2f98a2353601a48435649e3c5931e41f9e7f4ccb8f9a8faf2156a3632de223638f1e91d608c5a77660fa00633a591488498c5e37fec6
+DIST aubio-0.4.2.tar.bz2 304216 SHA256 1cc58e0fed2b9468305b198ad06b889f228b797a082c2ede716dc30fcb4f8f1f SHA512 b57b6d147b305a264f0055726f76a8452f784b556a7fda911f056adbedd2855048e93c0e21b9f359e3f442f1542189aff0c214dd85141e2e06048a07f47703ff WHIRLPOOL 1fa0c877261c82d095144c05f753dd5ea303838d48627edf18af4275f8b4aba0dbe5806bb2504bc2c5a2c169d5bd8edd76bcb3cd990abd7b42842d0223918270
diff --git a/media-libs/aubio/aubio-0.4.2.ebuild b/media-libs/aubio/aubio-0.4.2.ebuild
new file mode 100644
index 000000000000..9f5142f77429
--- /dev/null
+++ b/media-libs/aubio/aubio-0.4.2.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='threads(+)'
+
+inherit distutils-r1 waf-utils multilib eutils
+
+DESCRIPTION="Library for audio labelling"
+HOMEPAGE="http://aubio.org/"
+SRC_URI="http://aubio.org//pub/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc double-precision examples ffmpeg fftw jack libav libsamplerate sndfile python"
+
+RDEPEND="
+	ffmpeg? (
+		!libav? ( >=media-video/ffmpeg-2.6:0= )
+		libav? ( >=media-video/libav-9:0= )
+	)
+	fftw? ( sci-libs/fftw:3.0 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	python? ( dev-python/numpy[${PYTHON_USEDEP}] ${PYTHON_DEPS} )
+	sndfile? ( media-libs/libsndfile )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	app-text/txt2man
+	doc? ( app-doc/doxygen )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+DOCS=( AUTHORS ChangeLog README.md )
+PYTHON_SRC_DIR="${S}/python"
+
+src_prepare() {
+	sed -i -e "s:doxygen:doxygen_disabled:" wscript || die
+}
+
+src_configure() {
+	python_setup
+	waf-utils_src_configure \
+		--enable-complex \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable double-precision double) \
+		$(use_enable fftw fftw3f) \
+		$(use_enable fftw fftw3) \
+		$(use_enable ffmpeg avcodec) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable sndfile)
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	waf-utils_src_compile --notests
+
+	if use doc; then
+		cd "${S}"/doc || die
+		doxygen full.cfg || die
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	waf-utils_src_compile --alltests
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_test
+	fi
+}
+
+src_install() {
+	waf-utils_src_install
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		DOCS="" distutils-r1_src_install
+		newdoc README README.python
+	fi
+
+	if use doc; then
+		dohtml -r doc/full/html/.
+		dodoc doc/*.txt
+	fi
+
+	if use examples; then
+		# install dist_noinst_SCRIPTS from Makefile.am
+		dodoc -r examples
+	fi
+}