media-libs/zimg: Drop .la files

Closes: https://bugs.gentoo.org/847520
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 55 insertions, 1 deletions

diff --git a/media-libs/zimg/zimg-3.0.4-r1.ebuild b/media-libs/zimg/zimg-3.0.4-r1.ebuild
new file mode 100644
index 000000000000..ffef62a46080
--- /dev/null
+++ b/media-libs/zimg/zimg-3.0.4-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/sekrit-twc/zimg"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/sekrit-twc/zimg/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	S="${WORKDIR}/${PN}-release-${PV}/"
+fi
+inherit autotools multilib-minimal
+
+DESCRIPTION="Scaling, colorspace conversion, and dithering library"
+HOMEPAGE="https://github.com/sekrit-twc/zimg"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+IUSE="debug static-libs test"
+RESTRICT="!test? ( test )"
+DEPEND="test? ( dev-cpp/gtest )"
+
+PATCHES=(
+	"${FILESDIR}/system-gtest.patch"
+	"${FILESDIR}/backport-e29571f-issue-175.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable debug) \
+		$(use_enable static-libs static) \
+		$(use_enable test unit-test)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	if ! use static-libs; then
+		find "${ED}" -type f -name '*.la' -delete || die
+	fi
+}
diff --git a/media-libs/zimg/zimg-9999.ebuild b/media-libs/zimg/zimg-9999.ebuild
index 2c7c54c43cfe..1db3c69e1757 100644
--- a/media-libs/zimg/zimg-9999.ebuild
+++ b/media-libs/zimg/zimg-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 if [[ ${PV} = *9999* ]] ; then
 	EGIT_REPO_URI="https://github.com/sekrit-twc/zimg"
@@ -30,3 +30,10 @@ multilib_src_configure() {
 		$(use_enable debug) \
 		$(use_enable static-libs static)
 }
+
+multilib_src_install_all() {
+	einstalldocs
+	if ! use static-libs; then
+		find "${ED}" -type f -name '*.la' -delete || die
+	fi
+}