proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

4 files changed, 140 insertions, 0 deletions

diff --git a/media-libs/raptor/Manifest b/media-libs/raptor/Manifest
new file mode 100644
index 000000000000..25d5a7931254
--- /dev/null
+++ b/media-libs/raptor/Manifest
@@ -0,0 +1,2 @@
+DIST raptor2-2.0.14.tar.gz 1877454 SHA256 cb447b7c684cbe60f1266d622691fd20fdcf7b91f4a470c6de5fc8e8961df1b2 SHA512 399e23f2c549df8f1d709d67129d3fcf7899a8cdcdd8071c165f2b4106f397cce05fc69a6d7b176857011bf95723c0909b6510eded12f82217f89925bc1ba7c2 WHIRLPOOL dae2b80f3c0e82a9340b096ca52e89b8ccc6c849a98a7744d648f68b75dec1ff615e008a334bc7c0cc54259c9dcc07dfd6079805a0345aa7d89c9058cfd1656b
+DIST raptor2-2.0.9.tar.gz 1788163 SHA256 e26fb9c18e6ebf71100f434070d50196a21d592b715e361850c3b4e789b5f6ef SHA512 da4a7d28c6f8ab1d3ada7b495c0bee47adcaaf2ff3303471b986a63c22b6f190ad7e258bf0b344730cd3af24183baadefbfc6a0fd703f8466f62f9bf57dbaf2a WHIRLPOOL 80ab896bf91ce86db175141b1d609013c0bcd02601e7bf7889d2b6223744f5c91cd25fb76fc747cf30728b194cca2beae44f10c02eae10e8a386dc9da10e9544
diff --git a/media-libs/raptor/metadata.xml b/media-libs/raptor/metadata.xml
new file mode 100644
index 000000000000..20b42e75e861
--- /dev/null
+++ b/media-libs/raptor/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>sound</herd>
+  <use>
+    <flag name="json">Enable support for JSON parsing</flag>
+  </use>
+</pkgmetadata>
diff --git a/media-libs/raptor/raptor-2.0.14.ebuild b/media-libs/raptor/raptor-2.0.14.ebuild
new file mode 100644
index 000000000000..c89d546ba8b5
--- /dev/null
+++ b/media-libs/raptor/raptor-2.0.14.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils libtool
+
+MY_PN=${PN}2
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="The RDF Parser Toolkit"
+HOMEPAGE="http://librdf.org/raptor/"
+SRC_URI="http://download.librdf.org/source/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
+SLOT="2"
+KEYWORDS="alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+curl debug json static-libs unicode"
+
+RDEPEND="dev-libs/libxml2
+	dev-libs/libxslt
+	curl? ( net-misc/curl )
+	json? ( dev-libs/yajl )
+	unicode? ( dev-libs/icu:= )
+	!media-libs/raptor:0"
+DEPEND="${RDEPEND}
+	>=sys-devel/bison-3
+	>=sys-devel/flex-2.5.36
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS="AUTHORS ChangeLog NEWS NOTICE README"
+
+src_prepare() {
+	elibtoolize # Keep this for ~*-fbsd
+}
+
+src_configure() {
+	# FIXME: It should be possible to use net-nntp/inn for libinn.h and -linn!
+
+	local myconf='--with-www=xml'
+	use curl && myconf='--with-www=curl'
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable debug) \
+		$(use unicode && echo --with-icu-config="${EPREFIX}"/usr/bin/icu-config) \
+		$(use_with json yajl) \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		${myconf}
+}
+
+src_test() {
+	emake -j1 test
+}
+
+src_install() {
+	default
+	dohtml {NEWS,README,RELEASE,UPGRADING}.html
+	prune_libtool_files --all
+
+	# http://bugs.gentoo.org/467768
+	local _rdocdir=/usr/share/doc/${PF}/html/${MY_PN}
+	[[ -d ${ED}/${_rdocdir} ]] && dosym ${_rdocdir} /usr/share/gtk-doc/html/${MY_PN}
+}
diff --git a/media-libs/raptor/raptor-2.0.9.ebuild b/media-libs/raptor/raptor-2.0.9.ebuild
new file mode 100644
index 000000000000..e83fc8a73bab
--- /dev/null
+++ b/media-libs/raptor/raptor-2.0.9.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils libtool
+
+MY_PN=${PN}2
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="The RDF Parser Toolkit"
+HOMEPAGE="http://librdf.org/raptor/"
+SRC_URI="http://download.librdf.org/source/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
+SLOT="2"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+curl debug json static-libs unicode"
+
+RDEPEND="dev-libs/libxml2
+	dev-libs/libxslt
+	curl? ( net-misc/curl )
+	json? ( dev-libs/yajl )
+	unicode? ( dev-libs/icu:= )
+	!media-libs/raptor:0"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS="AUTHORS ChangeLog NEWS NOTICE README"
+
+src_prepare() {
+	elibtoolize # Keep this for ~*-fbsd
+}
+
+src_configure() {
+	# FIXME: It should be possible to use net-nntp/inn for libinn.h and -linn!
+
+	local myconf='--with-www=xml'
+	use curl && myconf='--with-www=curl'
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable debug) \
+		$(use unicode && echo --with-icu-config="${EPREFIX}"/usr/bin/icu-config) \
+		$(use_with json yajl) \
+		--with-xml2-config=no \
+		--with-curl-config=no \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		${myconf}
+}
+
+src_test() {
+	emake -j1 test
+}
+
+src_install() {
+	default
+	dohtml {NEWS,README,RELEASE,UPGRADING}.html
+	prune_libtool_files --all
+	dosym /usr/share/doc/${PF}/html/${MY_PN} /usr/share/gtk-doc/html/${MY_PN}
+}