media-libs/libzmf: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 18 insertions, 15 deletions

diff --git a/media-libs/libzmf/libzmf-0.0.2.ebuild b/media-libs/libzmf/libzmf-0.0.2-r1.ebuild
index 4d3dc28e21a3..f20a76d51b4a 100644
--- a/media-libs/libzmf/libzmf-0.0.2.ebuild
+++ b/media-libs/libzmf/libzmf-0.0.2-r1.ebuild
@@ -1,20 +1,21 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
-EGIT_REPO_URI="git://gerrit.libreoffice.org/libzmf"
-[[ ${PV} == 9999 ]] && inherit git-r3 autotools
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.libreoffice.org/libzmf"
+	inherit git-r3 autotools
+else
+	SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
+	KEYWORDS="amd64 ~arm arm64 ppc ppc64 ~riscv x86"
+fi
 
 DESCRIPTION="Library for parsing Zoner Callisto/Draw documents"
 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libzmf"
-[[ ${PV} == 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="amd64 ~arm arm64 ppc ppc64 ~riscv x86"
-
 IUSE="debug doc test tools"
 RESTRICT="!test? ( test )"
 
@@ -26,25 +27,27 @@ RDEPEND="
 "
 DEPEND="${RDEPEND}
 	dev-libs/boost
-	doc? ( app-doc/doxygen )
 	test? ( dev-util/cppunit )
 "
+BDEPEND="doc? ( app-doc/doxygen )"
 
 src_prepare() {
 	default
-	[[ ${PV} == 9999 ]] && eautoreconf
+	[[ ${PV} == *9999 ]] && eautoreconf
 }
 
 src_configure() {
-	econf \
-		--disable-werror \
-		$(use_enable debug) \
-		$(use_with doc docs) \
-		$(use_enable test tests) \
+	local myeconfargs=(
+		--disable-werror
+		$(use_enable debug)
+		$(use_with doc docs)
+		$(use_enable test tests)
 		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
 	default
-	find "${D}" -name '*.la' -delete || die
+	find "${ED}" -name '*.la' -delete || die
 }