media-libs/gexiv2: fix deps, add py3.8, disable vala tool

* Fix gexiv2 minimum dep per meson, re-sort in appearance order
* Fix python dep to be USE=python conditional; add missing pygobject
* Add python3_8 to PYTHON_COMPAT - just simple g-i overrides that
  should be OK with it, and appear to be on other distros
* Add missing gtk-doc docbook dep
* Disable a new vala requiring tool. This would really have to be
  conditional to USE=vala, possibly behind an extra USE flag. But
  it has questionable value and is not shipped by other distros
  either, so just unconditionally disable it for the time being

After this I can consider this appropriate for stabling

Bug: https://bugs.gentoo.org/711784
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 74 insertions, 0 deletions

diff --git a/media-libs/gexiv2/gexiv2-0.12.0-r1.ebuild b/media-libs/gexiv2/gexiv2-0.12.0-r1.ebuild
new file mode 100644
index 000000000000..2d14e15deaf4
--- /dev/null
+++ b/media-libs/gexiv2/gexiv2-0.12.0-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson python-r1 vala
+
+DESCRIPTION="GObject-based wrapper around the Exiv2 library"
+HOMEPAGE="https://wiki.gnome.org/Projects/gexiv2"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gexiv2.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://gnome/sources/${PN}/$(ver_cut 1-2)/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+LICENSE="LGPL-2.1+ GPL-2"
+SLOT="0"
+IUSE="gtk-doc +introspection python static-libs test +vala"
+REQUIRED_USE="
+	python? ( introspection ${PYTHON_REQUIRED_USE} )
+	test? ( python introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=media-gfx/exiv2-0.26:=
+	>=dev-libs/glib-2.38.0:2
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	python? ( ${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	test? ( media-gfx/exiv2[xmp] )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		-Dtools=false # requires vala, freshly promoted tool that some other distros don't ship yet either
+		# Prevents installation of python modules (uses install_data from meson
+		# which does not optimize the modules)
+		-Dpython2_girdir=no
+		-Dpython3_girdir=no
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi/overrides/
+		python_foreach_impl python_domodule GExiv2.py
+	fi
+}