media-gfx/imagemagick: Bump to versions 6.9.5.10 and 7.0.3.1

Package-Manager: portage-2.3.1
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

3 files changed, 180 insertions, 1 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index e5a21de28e36..60db4d61b334 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,5 +1,6 @@
 DIST ImageMagick-6.9.4-6.tar.xz 8785300 SHA256 c028642af5f4cbae864b4afd6ea96878191be64103ca9c7cc67612ec3cbb9dec SHA512 2984533e6b5c3e09d2e270c27ce9c3316499e622ed0b657e17baede5e380778d496626e3f47a32572a8c9a3a4b5257004ecf51b66ada762375516fbdffd0707d WHIRLPOOL 2ecb83b7f6790db17632eae822de64bd05b7bcb6839eb686e34f95c31ebeddc2023960005cf6d956d2692d79733b7f15e7a6355a0af2d98546f7c3e04c16b626
 DIST ImageMagick-6.9.4-7.tar.xz 8792244 SHA256 f54fc8dcdb328404d1f89ddebe75d603e22894d3786ca2f2a9677478135b4c86 SHA512 63f6baa85da88510c6afff85569f55fe0e543f9f46e2e90f7c8f78dc83907656ed689781856d0e6a9c959deffe601a654cda1057fec62d03d2c5f54ed3f2f84e WHIRLPOOL 1c5c95527d10219f4e82ea8645c571b6005c764ed286c11e6b3eebb1944c9ff880b5f9030bd6bf7c5bc4917ada50878b343a0a4c8930f7b59b8007f3119d46a3
+DIST ImageMagick-6.9.5-10.tar.xz 8794440 SHA256 2805ab7945ca92251172335da992df800bcc09fee993eeb4711b20c53efeb233 SHA512 7ee467cf8b1776300c12f135c7fea73afe888d4592c2008e76e578afa436efadccc62e7f2fd9d356aeb8559cc5ff9168ee477bab5474f7495a332756aba294bb WHIRLPOOL 3105e524182f81d1210fd3f56c3457259c04d3d95d5a5a118f0854dd5f5851e43c70256f915221a0c3dd772e344fc5d9e1d36c3d2b77fccde68d70f66471c299
 DIST ImageMagick-6.9.5-5.tar.xz 8784240 SHA256 b3b5cc1989a53b8847ffdc3b5ed740ba0c9c4e9b103cbbac7d0a78e5b7d2936f SHA512 b7ac42dbbcc243a685781ab83611d78e7535a63df6c230e9281b11d67232675197c9ed505e5dd15ff89acc8dd0dd4488728cc24dc93accbad914effe0772324c WHIRLPOOL 85be996dad1f3d38bfc426b810d15b8d47d2c353b9028f2d2be2c82732fdd82b602aa7ff36b95733f3e5758893edd0f6f257fde41dc9d8b6bfa1d8d02f4dbd23
 DIST ImageMagick-6.9.5-9.tar.xz 8778128 SHA256 9c4f300daae165a6bcf46779876f9361a958076f8cd59fa203d84c70ba5bc183 SHA512 3aff67710305e3427e2effab5bd5b10c9f55ca9b755704cdea169dbe3653fe919ae603a37fb3d7c105b61c930d4652cf488f7a7ec0a2d847bfb66b8f6eb1db43 WHIRLPOOL badb7dc7f72b9872865c6140cc69ee7bff8978536ab0c6439b26bb60b441d28313e053374e92eaa9b19ab2882189803e7749a261df59ea121fb010f2d6a09802
-DIST ImageMagick-7.0.3-0.tar.xz 8289784 SHA256 3c8a3c49e61fdc4331a5695375da67c14a8d04b92ce53297cd6a403af9a502ba SHA512 ab0b99d3f656c68f32336561b0679792c876ff81eb172cc0ac48dd5217960d2aef4d01281517ec94548cf1783f3fd9b7618d9909fe00945ce4b95afd182c0aa3 WHIRLPOOL 2f1475783fb9a3632ad2cc33d2775efed485f4975e6cf14496958e02e31b55dc37091996f4f3dbeed797cd9c72c5ad83ae4f216b52bd9e302e8c87cc40c1fa6d
+DIST ImageMagick-7.0.3-1.tar.xz 8292812 SHA256 9d9acda9061655569ff234bcc9a9e1d7c77c7d8b8e0035533fdb40b57846554b SHA512 4abfed5502ea408911b54225d8a45fd0e7c090c61c7950c031b0629dc543b41166dbaa1f743fdceaaab483db1ab5d5bb70dec595a5f7f87c687088d47db579bd WHIRLPOOL 77bf4022f953b211d5d1aa0f400f894dd92080b11144542c08b9a7376a4e74b0487b24ec074d9c68bd8ce028ef69dbda3514b7380b5404c7a90eaaf37d5ea7e6
diff --git a/media-gfx/imagemagick/imagemagick-7.0.3.0.ebuild b/media-gfx/imagemagick/imagemagick-6.9.5.10.ebuild
index 47260e1ab822..47260e1ab822 100644
--- a/media-gfx/imagemagick/imagemagick-7.0.3.0.ebuild
+++ b/media-gfx/imagemagick/imagemagick-6.9.5.10.ebuild
diff --git a/media-gfx/imagemagick/imagemagick-7.0.3.1.ebuild b/media-gfx/imagemagick/imagemagick-7.0.3.1.ebuild
new file mode 100644
index 000000000000..47260e1ab822
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.3.1.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+	use q64 && depth=64
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	CONFIG_SHELL=$(type -P bash) \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k openjp2) \
+		$(use_with lcms) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp \
+		--with-gcc-arch=no-automagic
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/ati/card:/dev/dri/card"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}